topic Re: how to extract a table name from string in SAS Enterprise Guide

how to extract a table name from string

JeffSAS — Wed, 15 Feb 2023 19:51:16 GMT

I want to extract the table name from the strings.

data a;
input x $65.;
cards;
if p < 0.5 then no error: put the table abc.story_chapt_2 on the floor
if p > 1.0 then with error: put the table def.cheeze on the floor
if p < 0.5 then no error: put the table xyz.fiction_book4 on the floor
;
run;

the output i want is

abc.story_chapt_2
def.cheeze
xyz.fiction_book4

Re: how to extract a table name from string

ballardw — Wed, 15 Feb 2023 20:33:45 GMT

Will the name always follow the word "table"? If so this works, at least for your example

data a;
input x $65.;
length tablename $ 41;
tablename =scan(x,findw(x,'TABLE',' ','IE',1)+1,' ');
cards;
if p < 0.5 then no error: put the table abc.story_chapt_2 on the floor
if p > 1.0 then with error: put the table def.cheeze on the floor
if p < 0.5 then no error: put the table xyz.fiction_book4 on the floor
;
run;

Re: how to extract a table name from string

Ksharp — Thu, 16 Feb 2023 11:56:16 GMT

data a;
input x $65.;
pid=prxparse('/[_a-z]\w*\.[_a-z]\w*/');
call prxsubstr(pid,x,p,l);
if p then want=substr(x,p,l);
drop pid p l;
cards;
if p < 0.5 then no error: put the table abc.story_chapt_2 on the floor
if p > 1.0 then with error: put the table def.cheeze on the floor
if p < 0.5 then no error: put the table xyz.fiction_book4 on the floor
;
run;