SAS generate sequence number by group and accumulate

MM88 — Fri, 06 May 2022 06:36:34 GMT

Hi experts,

I need to create a sequence number by group in SAS and accumulate by group.

I have a dataset with a column that it says if an event occurs o not as well as the time in case of occurrence. I also have initial datetime and end datetime which I don't represent in my example data.

Example data:

Event	Time
0	0
0	0
1	0.3
1	0.4
1	0.4
0	0
0	0
1	0.1
1	0.5

I need to assign a sequence number for each group where the event happens and create a cumulative.

It should look something like:

Result data:

Event	Time	Group	Cumulative
0	0	0	0
0	0	0	0
1	0.3	1	1.1
1	0.4	1	0
1	0.4	1	0
0	0	0	0
0	0	0	0
1	0.1	2	0.6
1	0.5	2	0

I was using the retain function with no luck.

Thanks for your suggestions.
Regards

Re: SAS generate sequence number by group and accumulate

PeterClemmensen — Fri, 06 May 2022 08:44:21 GMT

data have;
input Event Time;
datalines;
0 0
0 0
1 0.3
1 0.4
1 0.4
0 0
0 0
1 0.1
1 0.5
;

data want(drop = c g);
   c = 0;
   do _N_ = 1 by 1 until (last.event);
      set have;
      by event notsorted;
      c + time;
      if first.event and event then g + 1;
   end;
   
   do _N_ = 1 to _N_;
      set have;
      group = ifn(event, g, 0);
      cumulative = ifn(_N_ = 1, c, 0);
      output;
   end;
run;

Result:

Event  Time  group  cumulative
0      0.0   0      0.0
0      0.0   0      0.0
1      0.3   1      1.1
1      0.4   1      0.0
1      0.4   1      0.0
0      0.0   0      0.0
0      0.0   0      0.0
1      0.1   2      0.6
1      0.5   2      0.0

topic Re: SAS generate sequence number by group and accumulate in SAS Enterprise Guide

SAS generate sequence number by group and accumulate

Re: SAS generate sequence number by group and accumulate