topic Re: Print output is different to data output for proc summary in SAS Enterprise Guide

Print output is different to data output for proc summary

dtha2622 — Fri, 25 Mar 2022 06:17:41 GMT

I'm using proc summary to calculate some quintiles, and I'm trying to get it in an output so it's easier to copy and paste across.

proc summary data=example min q1 median q3 max print;
var variable_1 variable_2;
output out=example_quintiles;
run;

I ran that and get the results in the format I want printed

However I get something completely different in the output data, which makes it more difficult to copy and paste.

Any ideas?

Re: Print output is different to data output for proc summary

Kurt_Bremser — Fri, 25 Mar 2022 08:36:23 GMT

Sadly, the default OUTPUT structure does not honor the statistics set in the PROC MEANS statement, so we need to beat the output into shape:

(using SASHELP.CLASS as an example)

proc summary data=sashelp.class min q1 median q3 max print;
var height weight;
output out=summary min= q1= median= q3= max= / autoname;
run;

proc transpose
  data=summary
  out=long1
;
var height: weight:;
run;

data long2;
set long1;
varname = scan(_name_,1,"_");
stat = scan(_name_,2,"_");
run;

proc transpose
  data=long2
  out=want (drop=_name_)
;
by varname;
var col1;
id stat;
run;

Re: Print output is different to data output for proc summary

data_null__ — Fri, 25 Mar 2022 13:29:51 GMT

You can use ODS and the STACKODS PROC statement option to get this data directly.

ods select none;
proc summary data=sashelp.class min q1 median q3 max print stackods;
   var height weight;
   ods output summary=summary;
   run;
ods select all;
proc print data=summary;
   run;

@Kurt_Bremser wrote:

Sadly, the default OUTPUT structure does not honor the statistics set in the PROC MEANS statement, so we need to beat the output into shape:

(using SASHELP.CLASS as an example)
proc summary data=sashelp.class min q1 median q3 max print;
var height weight;
output out=summary min= q1= median= q3= max= / autoname;
run;

proc transpose
  data=summary
  out=long1
;
var height: weight:;
run;

data long2;
set long1;
varname = scan(_name_,1,"_");
stat = scan(_name_,2,"_");
run;

proc transpose
  data=long2
  out=want (drop=_name_)
;
by varname;
var col1;
id stat;
run;

Re: Print output is different to data output for proc summary

ballardw — Fri, 25 Mar 2022 14:11:43 GMT

Copy and Paste what?