topic Re: How to create a format from concatenated values? in SAS Enterprise Guide

How to create a format from concatenated values?

RobertWF1 — Mon, 20 Dec 2021 04:56:34 GMT

I'm trying to create the binary format binary3. by concatenating the values 'binary', n, and '.', where n=3 is a value that will be read in from the data step (or possibly a macro variable).

So far the following code doesn't work - it should output a list of binary values for the integers 1 through 8 in the log file. Any ideas what's wrong with my format statement?

data _null_;
n = 3;
rows = 2**n;
/** construct one row at a time **/
format = cats('binary', char(n,1), '.');
do i = 1 to rows;
put @1 i format;
/* put @1 i binary3.;*/
end;
run;

Re: How to create a format from concatenated values?

andreas_lds — Mon, 20 Dec 2021 06:24:02 GMT

Only the putc/putn function allow dynamic formats.

You could move the format-name to a macro-variable:

%let n = 3;
%let binaryformat = binary&n..;

data _null_;
   rows = 2**&n.;
   
   do i = 1 to rows;
      put i &binaryformat.;
      /* put @1 i binary3.;*/
   end;
run;

Re: How to create a format from concatenated values?

yabwon — Mon, 20 Dec 2021 12:20:41 GMT

data _null_;
  n = 3;
  rows = 2**n;
  /** construct one row at a time **/
  format = cats('binary', n, '.');
  do i = 1 to rows;
    b = putn(i, format);
    put @1 i b;
  end;
run;

Re: How to create a format from concatenated values?

RobertWF1 — Mon, 20 Dec 2021 15:38:55 GMT

Fantastic, thank you Andreas!

Re: How to create a format from concatenated values?

RobertWF1 — Mon, 20 Dec 2021 15:39:35 GMT

Beautiful, thank you!