topic Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO in SAS Enterprise Guide

Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNOSIS_

AmitChop7391 — Tue, 06 Nov 2018 07:52:27 GMT

Hi,

I'm getting the following errors on running my code:

ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNOSIS_25_CODE) are different.
ERROR: Too few variables defined for the dimension(s) specified for the array Diag.

/**** Pulling Patients ***/
Data AC_1 (keep = a b c);
set abc;
array Diag {28} $ HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNOSIS_25_CODE;
RespInd = 0;
do i = 1 to dim(Diag);
If Diag {i} in ('E850','E851', 'E852','E853','E854','E858','E8589','E859') then RespInd = 1;
end;
drop i;
run;

Please help!

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

andreas_lds — Tue, 06 Nov 2018 08:02:04 GMT

No text is allowed after the numbers if you want to use ranges that way. If you don't have any other variable starting with "header_diagnosis_", try using

array Diag {28} $ HEADER_DIAGNOSIS_:;

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

AmitChop7391 — Tue, 06 Nov 2018 08:12:51 GMT

Now, I got this error:

array Diag {26} $ HEADER_DIAGNOSIS_:;
ERROR: Too few variables defined for the dimension(s) specified for the array Diag.

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

PeterClemmensen — Tue, 06 Nov 2018 08:22:54 GMT

Try this

array Diag {*} $ HEADER_DIAGNOSIS_:;

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

AmitChop7391 — Tue, 06 Nov 2018 08:34:35 GMT

Thanks, it is working but it is taking too much time as compared to Proc sql when I declared 26 variables there.

Thanks!

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

andreas_lds — Tue, 06 Nov 2018 08:39:05 GMT

@AmitChop7391 wrote:

Thanks, it is working but it is taking too much time as compared to Proc sql when I declared 26 variables there.

Thanks!

Can't believe, that in that case a data-step is slower that proc sql. Please post the code.

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

AmitChop7391 — Tue, 06 Nov 2018 08:41:23 GMT

Data AC_1;
set abc (keep = HEADER_DIAGNOSIS_1_CODE
HEADER_DIAGNOSIS_2_CODE
HEADER_DIAGNOSIS_3_CODE
HEADER_DIAGNOSIS_4_CODE
HEADER_DIAGNOSIS_5_CODE
HEADER_DIAGNOSIS_6_CODE
HEADER_DIAGNOSIS_7_CODE
HEADER_DIAGNOSIS_8_CODE
HEADER_DIAGNOSIS_9_CODE
HEADER_DIAGNOSIS_10_CODE
HEADER_DIAGNOSIS_11_CODE
HEADER_DIAGNOSIS_12_CODE
HEADER_DIAGNOSIS_13_CODE
HEADER_DIAGNOSIS_14_CODE
HEADER_DIAGNOSIS_15_CODE
HEADER_DIAGNOSIS_16_CODE
HEADER_DIAGNOSIS_17_CODE
HEADER_DIAGNOSIS_18_CODE
HEADER_DIAGNOSIS_19_CODE
HEADER_DIAGNOSIS_20_CODE
HEADER_DIAGNOSIS_21_CODE
HEADER_DIAGNOSIS_22_CODE
HEADER_DIAGNOSIS_23_CODE
HEADER_DIAGNOSIS_24_CODE
HEADER_DIAGNOSIS_25_CODE
);
array Diag {*} $ HEADER_DIAGNOSIS_:;
RespInd = 0;
do i = 1 to dim(Diag);
If Diag {i} in ('E850','E851', 'E852','E853','E854','E858','E8589','E859') then RespInd = 1;
end;
drop i;
run;

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

PeterClemmensen — Tue, 06 Nov 2018 08:48:48 GMT

Remember, you can se the colon operator in the keep= option as well.

Also, I think the IN Operator in

If Diag {i} in ('E850','E851', 'E852','E853','E854','E858','E8589','E859') then RespInd = 1;

is what slows things down. You are probably better off using the INDEX or FIND function.

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

data_null__ — Tue, 06 Nov 2018 13:46:09 GMT

Try flipping the question. You could also unroll the iteration over E array.

data have;
   infile cards dsd missover;
   id + 1;
   input (Header_diagnosis_1-Header_diagnosis_6)(:$6.);
   cards;
E850,E851, E853,E854,E858
E850,E851, E858
G850,C851, D858
;;;;
   run;
proc print;
   run;
data respint;
   set have;
   array Diag [*] $ HEADER_DIAGNOSIS_:;
   array e[8] $5 _temporary_ ('E850','E851', 'E852','E853','E854','E858','E8589','E859');
   RespInd = 0;
   do i = 1 to dim(e);
      if e[i] in diag then do;
         RespInd = 1;
         leave;
         end;
      end;
   drop i;
run;
proc print;
   run;

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

Astounding — Tue, 06 Nov 2018 13:57:31 GMT

Good suggestion, but note that buried in the logic is the LEAVE statement. You could get similar savings to the LEAVE statement by changing your original DO loop:

do i = 1 to dim(Diag) until (respind=1);

That way, once a match is found, you won't need to check the remaining diagnosis codes.

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

andreas_lds — Tue, 06 Nov 2018 14:20:43 GMT

I am still wondering what proc sql code creates the result dataset faster then the data-step using leave or until.

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

data_null__ — Tue, 06 Nov 2018 15:13:32 GMT

@Astounding wrote:

Good suggestion, but note that buried in the logic is the LEAVE statement. You could get similar savings to the LEAVE statement by changing your original DO loop:

do i = 1 to dim(Diag) until (respind=1);

That way, once a match is found, you won't need to check the remaining diagnosis codes.

I think it called the "same difference".

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

AmitChop7391 — Tue, 13 Nov 2018 12:07:08 GMT

Thanks, I will try this one.

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

AmitChop7391 — Tue, 13 Nov 2018 12:08:38 GMT

Hey,

I need to check those codes in all diagnosis fields i.e Diagnosis_1 - Diagnosis_26.

Thanks,

Amit

Re: Help: ERROR: Alphabetic prefixes for enumerated variables (HEADER_DIAGNOSIS_1_CODE-HEADER_DIAGNO

Astounding — Tue, 13 Nov 2018 15:25:52 GMT

No, that's wrong.

Once you find a match and set RespInd=1, you no longer need to check the remaining diagnosis codes. All that would do is allow you to set RespInd to 1, when it is already 1.