topic Re: Do Loops or Data Step? in SAS Enterprise Guide

Do Loops or Data Step?

martin3 — Thu, 24 May 2018 15:46:22 GMT

have a source dataset that I need to get a column of distinct values and then "pivot" out the associated columns into a single new field.

Data source;

SomeID Acct Prod

ABC 1 Z

ABC 2 X

ACC 3 X

ADD 6 C

Results desired;

SomeID new field

ABC 1,Z;2,X

ACC 3,X

ADD 6,C

Thanks,

SAS EG 7.13

Re: Do Loops or Data Step?

novinosrin — Thu, 24 May 2018 15:51:16 GMT

I hope this helps

data have;
input SomeID   $     Acct   Prod $;
cards;
ABC            1          Z
ABC           2           X
ACC           3           X
ADD            6          C
;

data want;
set have;
by someid;
length new $50;
retain new;
if first.someid then new=catx(',',acct,prod);
else new=catx(',',new,acct,prod);
if last.someid;
run;

Re: Do Loops or Data Step?

ballardw — Thu, 24 May 2018 16:19:39 GMT

Can you describe exactly how that new field will be used in other processes? If you are doing much other than printing the result things get real ugly real fast.

Re: Do Loops or Data Step?

ballardw — Thu, 24 May 2018 16:23:53 GMT

@novinosrin

OP shows semicolons between the "row groups"

data want;
   set have;
   by someid;
   length new $50;
   retain new;
   if first.someid then new=catx(',',acct,prod);
   else new=catx(';',new,catx(',',acct,prod));
   if last.someid;
run;

And of course NEW may need to have a length defined to hold much more text than the example data provides.

Re: Do Loops or Data Step?

novinosrin — Thu, 24 May 2018 16:25:20 GMT

@ballardw Thank you sir. I really need to get my eyes tested. Time to wear glasses 😞

Re: Do Loops or Data Step?

ballardw — Thu, 24 May 2018 16:27:29 GMT

@novinosrin wrote:

@ballardw Thank you sir. I really need to get my eyes tested. Time to wear glasses 😞

I was trying to figure out just what this could be useful for so was looking for different delimiters.

Re: Do Loops or Data Step?

novinosrin — Thu, 24 May 2018 16:32:02 GMT

LOL Believe it or not, This isn't the first time that you brilliantly pointed out every bits of detail to correct me and I can't appreciate enough. I even told that to my parents(my mom in particular who taught me how to program using hash objects) and she opined "not to throw up codes when you are hung over, pay attention to every detail like @ballardw does"

There you go 🙂