topic Re: color column based on the cell (text) value in SAS Enterprise Guide

color column based on the cell (text) value

DME790 — Tue, 13 Mar 2018 04:30:50 GMT

Hi All,

I need to colour a row based on the text value in the cell value being BBB

data test;
	INPUT Target1 $Target2 TRAN;
	Datalines;
AAA 1 1
AAA	  1   1
BBB	  2   73
BBB	 3   2
DDD	 4 5
MVQ	 5 1
OOO	 6 1
OOO	 7 3
OTH	 8 1
OTH	 9 1
TTT	 10 1
TTT  11 5
TTT	 12 1
TTT	 13 2
YYY	 14 1
;
RUN;

Proc Report data=TEST;
	Column Target1 Target2 TRAN TransPCT;
	Define Target1 / DISPLAY 'Target1' style(column)=[cellwidth=4.0in];
	Define Target2 / DISPLAY 'Target2' style(column)=[cellwidth=3.0in];
	define Tran /  DISPLAY 'Transfers' f=comma8. SUM Analysis;
	Define TransPCT / COmputed 'Transfer %' f=Percent8.2;

	Compute Before;
		TransTOT = TRAN.SUM;
	ENDCOMP;

	Compute TransPCT;
		TransPCT = TRAN.sum / TransTOT;
	ENDCOMP;

	Rbreak after / SUmmarize;
RUN;

Current output looks like this, below is what I would like. Cheers

Dean

Target1	Target2	Transfers	Transfer %
AAA	1	1	1.01%
AAA	1	1	1.01%
BBB	2	73	73.74%
BBB	3	2	2.02%
DDD	4	5	5.05%
MVQ	5	1	1.01%
OOO	6	1	1.01%
OOO	7	3	3.03%
OTH	8	1	1.01%
OTH	9	1	1.01%
TTT	10	1	1.01%
TTT	11	5	5.05%
TTT	12	1	1.01%
TTT	13	2	2.02%
YYY	14	1	1.01%
		99	100.00%

Target1	Target2	Transfers	Transfer %
AAA	1	1	1.01%
AAA	1	1	1.01%
BBB	2	73	73.74%
BBB	3	2	2.02%
DDD	4	5	5.05%
MVQ	5	1	1.01%
OOO	6	1	1.01%
OOO	7	3	3.03%
OTH	8	1	1.01%
OTH	9	1	1.01%
TTT	10	1	1.01%
TTT	11	5	5.05%
TTT	12	1	1.01%
TTT	13	2	2.02%
YYY	14	1	1.01%
		99	100.00%

Re: color column based on the cell (text) value

Ksharp — Tue, 13 Mar 2018 13:21:09 GMT

Compute TransPCT;
		TransPCT = TRAN.sum / TransTOT;
		if Target1='BBB' then call define(_row_,'style','style={foreground=red}');
	ENDCOMP;

Re: color column based on the cell (text) value

Ksharp — Tue, 13 Mar 2018 13:35:52 GMT

data test;
	INPUT Target1 $Target2 TRAN;
	Datalines;
AAA 1 1
AAA	  1   1
BBB	  2   73
BBB	 3   2
DDD	 4 5
MVQ	 5 1
OOO	 6 1
OOO	 7 3
OTH	 8 1
OTH	 9 1
TTT	 10 1
TTT  11 5
TTT	 12 1
TTT	 13 2
YYY	 14 1
;
RUN;


Proc Report data=TEST nowd;
	Column Target1 Target2 TRAN TransPCT;
	Define Target1 / DISPLAY 'Target1' style(column)=[cellwidth=4.0in];
	Define Target2 / DISPLAY 'Target2' style(column)=[cellwidth=3.0in];
	define Tran /  DISPLAY 'Transfers' f=comma8. SUM Analysis;
	Define TransPCT / COmputed 'Transfer %' f=Percent8.2;

	Compute Before;
		TransTOT = TRAN.SUM;
	ENDCOMP;

	Compute TransPCT;
		TransPCT = TRAN.sum / TransTOT;
		if Target1=:'BBB' then call define(_row_,'style','style={foreground=red}');
	ENDCOMP;

	Rbreak after / SUmmarize;
RUN;

Re: color column based on the cell (text) value

DME790 — Tue, 13 Mar 2018 21:19:35 GMT

Thanks @Ksharp exactly what I required.

Cheers

Dean