topic Datalines with varying length in SAS Enterprise Guide

Datalines with varying length

Autotelic — Mon, 02 Oct 2017 10:11:37 GMT

Windows 10, SAS Base 9.4, SAS Enterprise Guide 7.1

I'm having trouble creating a dataset using datalines.

The code

Data test1;
    Infile datalines delimiter=",";
    Input str $ num;
    datalines;
abcdefghi,0
zyxwvut,1
;

yields

The str variable is truncated at the eigth character (by default). In order to try to fix this I tried adjusting the length:

Data test2;
    Infile datalines delimiter=",";
    Input str $9. num;
    datalines;
abcdefghi,0
zyxwvut,1
;

But this also doesn't do what I want since the numbers after the delimiter are being read into str:

How can I fix this?

Re: Datalines with varying length

ChrisBrooks — Mon, 02 Oct 2017 10:32:30 GMT

You just need a slight amendment - use a length statement first.

Data test2;
	length str $9;
    Infile datalines delimiter=",";
    Input str $ num;
    datalines;
abcdefghi,0
zyxwvut,1
;

run;

Re: Datalines with varying length

RW9 — Mon, 02 Oct 2017 10:39:38 GMT

Just to add to @ChrisBrooks excellent advice, you should read the manual on the sections about defaults so you understand what is going on. Because you have not previously set the length of a character variable, the default in SAS is to have a length of 8, therefore when the string is read in, only 8 characters can be present. The solution given explicitly defines the length of that variable to be 9 therefore can read in 9 characters. It is very important to always specify lengths (and types) on variables before you start to use them, otherwise you may not end up with the result you want.

With these data imports it is always useful (if from third party but maybe also on other scenarios too) to have a data specification document which details what each fields type, length, format, and possibly code list is, so that anyone picking up the data can easily see the data structure and can interpret it without ambiguity.

Re: Datalines with varying length

Kurt_Bremser — Mon, 02 Oct 2017 10:40:27 GMT

A very slight modification will make your second code work:

Data test2;
    Infile datalines delimiter=",";
    Input str :$9. num;
    datalines;
abcdefghi,0
zyxwvut,1
;

Re: Datalines with varying length

Autotelic — Mon, 02 Oct 2017 12:30:10 GMT

Can you tell me where to read about your solution ":". I can't find it at http://documentation.sas.com/?docsetId=lestmtsref&docsetTarget=n0oaql83drile0n141pdacojq97s.htm&docsetVersion=9.4&locale=pt

Re: Datalines with varying length

Kurt_Bremser — Mon, 02 Oct 2017 14:10:48 GMT

@Autotelic wrote:
Can you tell me where to read about your solution ":". I can't find it at http://documentation.sas.com/?docsetId=lestmtsref&docsetTarget=n0oaql83drile0n141pdacojq97s.htm&docsetVersion=9.4&locale=pt

It's part of list input: http://documentation.sas.com/?docsetId=lestmtsref&docsetTarget=n0lrz3gb7m9e4rn137op544ddg0v.htm&docsetVersion=9.4&locale=de