topic Re: Peculiar behaviour of find()? in SAS Enterprise Guide

Peculiar behaviour of find()?

DipeshGupta — Tue, 29 Aug 2017 13:33:56 GMT

Data Test3 ;
Set Test2 ;
Format o_String $2000. ;
if _N_ = 1 then do;
O_String = "" ;
end ;
O_String = catx(" , ", O_String, " ") ;
find = Find(O_String,O_Level) ;
O_String = catx(" , ", O_String, O_Level) ;
new = Find(O_String,O_Level) ;
Retain O_String ;
Run ;

I am confused as why the column named find is always showing zero when the column named new is showing the correct value.

As per my understanding only the first row in find should show a blank value otherwise it should also give some value but it is always giving a straight zero.

Can anyone help me with this..??

Re: Peculiar behaviour of find()?

Kurt_Bremser — Tue, 29 Aug 2017 13:35:35 GMT

When assigning find, you are testing for the presence of o_level before you append it to o_string, so find will be zero unless the same value for o_level was already on the dataset.

But you also made the mistake of assuming that a shorter string will consist of less characters for SAS, which it doesn't. The find() function will take the padding of o_level with blanks into account, and only find a position if the visible value of o_level can be found padded with blanks in o_string:

data test2;
input o_level $;
cards;
xxx
yyy
zzz
xxx
;
run;

data test3;
set test2;
format o_string $2000.;
retain o_string "";
o_string = catx(" , ",o_string," ");
find = find(o_string,trim(o_level));
o_string = catx(" , ",o_string,o_level);
new = find(o_string,o_level);
run;

So I used the trim() function in the first test.

Re: Peculiar behaviour of find()?

Kurt_Bremser — Tue, 29 Aug 2017 13:35:09 GMT

I also edited your subject line. "SAS Datastep" is very uninformative with respect to your question.

Re: Peculiar behaviour of find()?

DipeshGupta — Wed, 30 Aug 2017 06:06:15 GMT

Thankyou So Much.

It got it and the code worked.