topic Re: How to check if a macro variable contains certain strings? in SAS Enterprise Guide

How to check if a macro variable contains certain strings?

ayin — Mon, 17 Jul 2017 02:51:40 GMT

/* sample dataset */
data have;
  infile datalines dlm=",";
  input date $ value;
datalines;
05AUG2010,5
;
run;


/* macro to calculate percentage */
%macro test11;
%global valueMax;
%let valueMAX = 10;

data WORK.have_adj;
set WORK.have;

format perc best8.;
perc = value/&valueMAX.;
run;

%mend test11;


/* macro to execute */
%let dataName = test;
%macro runTEST;

 %if %sysfunc(find("&dataName.",'test')) ge 1 %then %do;   /* something wrong here */
    %test11; 
    %end; 

%mend runTEST;
%runTEST;

/* check whether macro 'test' has been executed */
%put _ALL_;
run;

The result suggests the macro 'test11' has not been executed. How to fix it?

Re: How to check if a macro variable contains certain strings?

Reeza — Mon, 17 Jul 2017 03:05:26 GMT

Remove the quotes from the macro variable in the FIND function.

Modified your code for testing to make it easier:

%macro runTEST(dataName);

 %if %sysfunc(find(&dataName.,test)) ge 1 %then %do;   /* something wrong here */
    %put FOUND TEST;
    %end; 
   %else %do;
   	%put NO TEST;
   %end;

%mend runTEST;
%runTEST(test);
%runTEST(hello_test123);
%runTEST(random);

Re: How to check if a macro variable contains certain strings?

ayin — Mon, 17 Jul 2017 03:20:36 GMT

Thank you @Reeza for both the answer and tips! That solves the problem.

Re: How to check if a macro variable contains certain strings?

Ksharp — Mon, 17 Jul 2017 13:02:39 GMT

%macro runTEST(dataName);

 %if %index(&dataName.,test) %then %do;   /* something wrong here */
    %put FOUND TEST;
    %end; 
   %else %do;
   	%put NO TEST;
   %end;

%mend runTEST;
%runTEST(test)
%runTEST(hello_test123)
%runTEST(random)