topic User defined formats in SAS Enterprise Guide

User defined formats

Garik — Mon, 10 Jul 2017 10:12:39 GMT

Hi.

I have a problem on creation user defined formats.

So, I try to create my own formats by using my dataset and want to add to the last row the "Not Found" values, but my code deletes the last rows and adds the "Not Found" statement.

Please give me a hint. the code is below;

data control_format /view=control_format;
		
	set cuserv.ABC_General (drop=Quantity Retail_Price
                             rename=(N_Item_Name = Start
                                     Class = Label))
				            end = last;
		retain fmtname '$mdclass'
		       Type 'C';

			   if last then do;
			   Start = ' ';
			   HLO = 'O';
			   Label = 'Not Found';
			   end;
 
 run;


 proc format cntlin=control_format fmtlib;
 run;

User-Defined Formats

Garik — Mon, 10 Jul 2017 10:21:52 GMT

Hi.

I have a problem on creation user defined formats.

So, I try to create my own formats by using my dataset and want to add to the last row the "Not Found" values, but my code deletes the last rows and adds the "Not Found" statement.

Please give me a hint. the code is below;

data control_format /view=control_format;
		
	set cuserv.ABC_General (drop=Quantity Retail_Price
                             rename=(N_Item_Name = Start
                                     Class = Label))
				            end = last;
		retain fmtname '$mdclass'
		       Type 'C';

			   if last then do;
			   Start = ' ';
			   HLO = 'O';
			   Label = 'Not Found';
			   end;
 
 run;


 proc format cntlin=control_format fmtlib;
 run;

Re: User-Defined Formats

Astounding — Mon, 10 Jul 2017 10:24:39 GMT

If that's the only roadblock, it's easy to overcome. Add an OUTPUT statement in two places:

data control_format /view=control_format;
		
	set cuserv.ABC_General (drop=Quantity Retail_Price
                             rename=(N_Item_Name = Start
                                     Class = Label))
				            end = last;
		retain fmtname '$mdclass'
		       Type 'C';
                           output;
			   if last then do;
			   Start = ' ';
			   HLO = 'O';
			   Label = 'Not Found';
                           output;
			   end;
 
 run;


 proc format cntlin=control_format fmtlib;
 run;

Re: User defined formats

RW9 — Mon, 10 Jul 2017 10:32:12 GMT

You just need to control the output statement in the datastep (which is at the end by default):

data control_format;
  set cuserv.abc_general (drop=quantity retail_price rename=(n_item_name=start)) end=last;
  retain fmtname '$mdclass' type 'C';
  if last then do;
    output;
    start=' ';
    hlo='o';
    label='not found';
    output;
  end;
  else output;
run;