SAS EG4 and vb/vba

deleted_user — Tue, 23 Oct 2007 09:32:25 GMT

Hi guys,

We have some SAS EG programs that deal with data conversion/ manipulation which require some variable parameters e.g. library names and paths of input/output files. I want to create a vb/ asp front end to input these parameters and runs the EG project from this vb front end.

Any ideas how I can do this... I have researched and found some vb examples

http://support.sas.com/forums/thread.jspa?messageID=3007ி

But I don't know how sas eg takes or reads the parameters as input. Basically how do I feed these parameters/variables into SAS EG to use?

Hope someone can help?

Re: SAS EG4 and vb/vba

ChrisHemedinger — Fri, 26 Oct 2007 13:29:58 GMT

As you probably know, you can add parameters in an EG project and associate them with your SAS programs, queries, and tasks. Once those parameters are in place, you can use the automation interface to discover and assign values for those parameters.

Here is a simple example of scripting an EG project with parameters:
[pre]
Option Explicit
Dim app
Dim prjName
Dim prjObject
Dim parmList
Dim parm

prjName = "C:\temp\autowithparams.egp" 'Project Name

' start the app and open the project
Set app = CreateObject("SASEGObjectModel.Application.4")
Set prjObject = app.Open(prjName,"")

' discover the parameters
Set parmList = prjObject.Parameters
Wscript.Echo "Project has " & parmList.Count & " parameters."

' work with the first parameter
Set parm = parmList.Item(0)
WScript.Echo parm.Name & " parameter has default value of " & parm.DefaultValue
parm.Value = "M"

WScript.Echo parm.Name & " parameter has been set to value of " & parm.Value

' run the project
prjObject.Run

WScript.Echo parm.Name & " parameter has been set after Run to value of " & parm.Value

prjObject.Close
app.Quit
[/pre]

Chris

topic Re: SAS EG4 and vb/vba in SAS Enterprise Guide

SAS EG4 and vb/vba

Re: SAS EG4 and vb/vba