topic Re: Monthly Dummy Variables in SAS Enterprise Guide

Monthly Dummy Variables

claireluen — Fri, 06 Jun 2014 16:08:28 GMT

What's the easiest way to create monthly dummy variables in SAS Enterprise Guide? I already have a monthly variable 1-12. Thanks!

Re: Monthly Dummy Variables

PaigeMiller — Fri, 06 Jun 2014 16:18:30 GMT

You want to create "monthly dummy variables" but then you say "I already have monthly dummy variables".

I don't understand the request.

Re: Monthly Dummy Variables

claireluen — Fri, 06 Jun 2014 16:19:09 GMT

Sorry, I just corrected. I have a monthly variable.

I know how to do it using query builder to recode the monthly variable column 11 different times. Surely there is something easier.

Re: Monthly Dummy Variables

ChrisHemedinger — Fri, 06 Jun 2014 16:32:16 GMT

Something like this?

data setup (drop=n);
    length date 8; 
    length m1-m12 8; 
    format date date9.; 

    /* create 100 random-month dates */
    do n = 1 to 100; 
        date = mdy(max(1,round(ranuni(0)*12,1)),1,2014);
        output; 
    end; 
run; 

/* fill in the dummy var values */
data create_dummy (drop=i);
set setup;
array dummy m1-m12;
do i = 1 to 12; 
  /* yields 1 if the var number is the month, else 0 */
  dummy(i) = (month(date) = i);
end; 
run;

Yields:

Chris

Re: Monthly Dummy Variables

PaigeMiller — Fri, 06 Jun 2014 16:40:59 GMT

claireluen wrote:

I know how to do it using query builder to recode the monthly variable column 11 different times. Surely there is something easier.

I don't know if this is available through Enterprise Guide, but the easiest way I know of the create dummy variables is PROC GLMMOD.

Re: Monthly Dummy Variables

ChrisHemedinger — Fri, 06 Jun 2014 16:44:37 GMT

Ah, with your clarification it's even a bit easier than my original. You have a "Month" var that is set to 1 thru 12 already?

data setup (drop=n);
    length mon 8; 
    /* create 100 random-month dates */
    do n = 1 to 100; 
        mon = max(1,round(ranuni(0)*12,1));
        output; 
    end; 
run; 

/* fill in the dummy var values */
data create_dummy (drop=i);
set setup;
length m1-m12 8; 
array dummy m1-m12;
do i = 1 to 12; 
  /* yields 1 if the var number is the month, else 0 */
  dummy(i) = (mon = i);
end; 
run;

Re: Monthly Dummy Variables

ChrisHemedinger — Fri, 06 Jun 2014 16:55:11 GMT

And if you want a more "query-friendly" method, create a 12-row reference table (one for each month value). Example DATA step:

data ref(keep=month m1-m12);
    length month 8; 
    length m1-m12 8; 
    array dummy m1-m12;
    do outer = 1 to 12; 
        month=outer;
        do inner = 1 to 12; 
            dummy(inner) = (outer = inner);
        end; 
        output; 
    end; 
run;

And then JOIN that table with the original, using MONTH as the key.

Re: Monthly Dummy Variables

claireluen — Fri, 06 Jun 2014 16:55:20 GMT

Perfect, thanks.