topic Re: help on datetime macro please in SAS Enterprise Guide

help on datetime macro please

jimksas — Thu, 10 Jul 2014 07:14:32 GMT

Hello,

i want to set up filename ending with datetime as below on daily report...please help...

filename xyz_abc_20140710112330.txt

/*filename xyz_abc_yyyymmddhhmmss.txt*/

Thank you in advance...

Re: help on datetime macro please

Scott_Mitchell — Thu, 10 Jul 2014 07:32:05 GMT

How about this?

Create a custom format.

PROC FORMAT;

PICTURE YMDDT OTHER='%0Y%0M%0D%0H%0M%0S' (DATATYPE=DATETIME);

RUN;

Create macro variable containing the date and time of right now and use custom format.

DATA _NULL_;

CALL SYMPUTX ("FNAME","XYZ_ABC_"||TRIM(LEFT(PUT(DATETIME(),YMDDT.))));

RUN;

%PUT &FNAME.;

Re: help on datetime macro please

jimksas — Thu, 10 Jul 2014 08:09:43 GMT

YMDDT.

is giving error...format cannot ound and could not be loaded...

i am trying create macro for only datetime function not with filename, so i can write down like this....

filename xyz_abc_&fname.txt

Re: help on datetime macro please

RW9 — Thu, 10 Jul 2014 08:33:21 GMT

What does it say in the log with options mlogic sybolgen mprint. I would imagine that you would at least need in the filename statement %trim(&fname) to avoid extra spaces. Personally I wouldn't go with formats, but it depends on where you are getting the date and time from, is it today() function, a dataset etc.

data _null_;

call symput('FNAME',compress(put(today(),yymmdd10.),"- ")||compress(put(time(),time8.),": "));

run;

%put xyz_abc_&fname.;

Re: help on datetime macro please

Scott_Mitchell — Thu, 10 Jul 2014 08:45:04 GMT

Did you execute the Proc Format code first?

Re: help on datetime macro please

Kurt_Bremser — Thu, 10 Jul 2014 08:57:07 GMT

data _null_;

now=datetime();

dat1=datepart(now);tim1=put(timepart(now),time8.);

filname='xyz_abc'!!put(dat1,yymmddn8.)!!substr(tim1,1,2)!!substr(tim1,4,2)!!substr(tim1,7,2)!!'.txt';

call symput('filnam',filname);

run;

filename outfile "/path_to_the_directory/&filnam";

Re: help on datetime macro please

Tom — Thu, 10 Jul 2014 12:42:28 GMT

I would just use B8601DT. format. If you really do not want the T between the date and time parts you could use COMPRESS() function to remove it.

%let dt=%sysfunc(datetime(),B8601DT);

%put dt=&dt;

dt=20140710T083935

%let filename=xyz_abc_%sysfunc(compress(&dt,T)).txt ;

%put filename=&filename ;

filename=xyz_abc_20140710083935.txt

You can now use anywhere a physical filename is required.

filename outfile "&filename" ;

file "&filename" ;

Re: help on datetime macro please

jimksas — Thu, 10 Jul 2014 15:26:53 GMT

No Scott, i didn't run it ...may be that's why...- Thanks

Thanks all for your detail...many ways to do it... 🙂

I am using RW9 solution...