topic Capturing the last character in a variable value in SAS Enterprise Guide

Capturing the last character in a variable value

svetting — Mon, 23 Jun 2014 19:39:21 GMT

Hello all,

This may be a simple question, but I'm quite new to SAS. I'm trying to do a few things, but before I can do any of the substantive stuff, I first need to identify the cases where the values in a variable called LPCT end in a 0 or 5. The values in LPCT differ in length though so I don't know how to specify the position of the last integer in the value. Is there is a command for "last character" or "ends in" in SAS language?

I want to to this:

IF LPCT ends-in 0 OR LPCT ends-in THEN ROUNDED=1;

ELSE ROUNDED=0;

but I don't know the real SAS-words for ends-in. Some version of the SUBSTR function would be great too, but again, the values of LPCT are of varyng lengths so I can't specify a numeric position for the integer I want to capture...I need to just tell SAS to take the last number in the variable's value somehow.

I'm not sure if I'm being clear but I hope someone has some suggestion!

Re: Capturing the last character in a variable value

Linlin — Mon, 23 Jun 2014 19:51:14 GMT

data have;

input lpct;

cards;

2.5

;

data want;

set have;

if first(reverse(lpct)) in ('0','5') then rounded=1;

else rounded=0;

proc print;run;

Re: Capturing the last character in a variable value

yeshwanth — Mon, 23 Jun 2014 20:08:28 GMT

data y1;

input id LPCT $;

cards;

1 sam0

2 alex5

3 jason0

;

run;

data y2;

set y1;

required_output=substr(lpct,length(lpct),1);

run;

Hope this helps !!

Re: Capturing the last character in a variable value

Haikuo — Mon, 23 Jun 2014 20:48:01 GMT

The more, the merrier:

data y1;

input id LPCT $;

cards;

1 sam0

2 alex5

3 jason1

;

DATA WANT;

SET Y1;

ROUND=PRXMATCH('/[5|0]$/',strip(lpct))>0;

run;

Re: Capturing the last character in a variable value

Astounding — Mon, 23 Jun 2014 21:01:22 GMT

OK, then it's quiz time. Why does this attempt give the wrong answer?

round = reverse(lpct) in : ('0', '5');

Re: Capturing the last character in a variable value

PGStats — Mon, 23 Jun 2014 21:52:34 GMT

All solutions proposed so far have small weaknesses ...

With REVERSE, trailing spaces will become leading spaces, so you would want to TRIM first.

You would still need to compare the resulting string with "0" and "5"

The pipe character is not required in the pattern

data y1;

input id lpct $;

datalines;

1 sam0

2 alex5

3 jason1

;

DATA WANT;

SET Y1;

ROUNDED = CHAR(lpct, LENGTH(lpct)) in ("0", "5");

run;

Re: Capturing the last character in a variable value

Haikuo — Mon, 23 Jun 2014 23:10:58 GMT

:smileylaugh:

Re: Capturing the last character in a variable value

Ksharp — Tue, 24 Jun 2014 14:21:18 GMT

If I guess right. lpct after reversing ,it should be starting with BLANK .

Re: Capturing the last character in a variable value

Astounding — Tue, 24 Jun 2014 15:24:08 GMT

Yes, that's the issue. I wasn't sure anyone would answer on this, since PG Stats hinted at the problem with his comment about Linlin's solution. When reversing generates a leading blank, both my quiz and Linlin's solution face this issue.