topic Re: combine this into single variable in SAS Software for Learning Community

combine this into single variable

animesh123 — Wed, 10 Aug 2022 15:03:35 GMT

ID NAME
1 Animesh

1 Mardi

1 ABC

How to combine this into single variable

Output should be :- 1 Animesh Mardi abc

Re: combine this into single variable

Reeza — Wed, 10 Aug 2022 15:07:43 GMT

proc sort data=have;
    by ID;
run;

**********************************************************************;
*Use RETAIN and BY group processing to combine the information;
**********************************************************************;
data want_option1;
    set have;
    by ID;
    length combined $100.;
    retain combined;

    if first.ID then
        combined=name;
    else
        combined=catx(', ', combined, name);

    if last.ID then
        output;
run;

proc transpose data=have out=wide prefix=name_;
    by ID;
    var name;
run;

data want_option2;
    set wide;
    length combined $100.;
    combined=catx(', ', of name_:);
run;

@animesh123 wrote:

ID NAME
1 Animesh

1 Mardi

1 ABC

How to combine this into single variable

Output should be :- 1 Animesh Mardi abc

Re: combine this into single variable

PeterClemmensen — Wed, 10 Aug 2022 17:15:54 GMT

Try this. I added an extra ID to clarify that it handles multiple by groups.

data have;
input ID NAME $;
datalines;
1 Animesh 
1 Mardi   
1 ABC     
2 Animesh 
2 Mardi   
2 ABC     
;

data want(drop = name);
   do until (last.ID);
      set have;
      by ID;
      length n $200;
      n = catx(' ', n, name);
   end;
run;