topic Re: Select all that apply variable to binary variables in SAS Software for Learning Community

Select all that apply variable to binary variables

mraposa1 — Thu, 02 Jun 2022 23:16:42 GMT

I have a dataset from a survey where one of the questions was select all that apply. When exported from Qualtrics to Excel, the variable is in this format:

Obs	Covid
1	1,10,11,12,13,14
2	1,12

There are 16 potential response options. I am stuck how to create binary variables for each response option without hardcoding everything in excel. I ultimately want to determine how many observations selected each response option.

Re: Select all that apply variable to binary variables

Reeza — Fri, 03 Jun 2022 00:38:00 GMT

data have;
infile cards dsd;
input obs $ COVID : $20.;
cards;
"1", "1,10,11,12,13,14"
"2", "1,12"
;;;;
run;

data binary;
set have;

nwords = countw(covid);

array _covid(14) covid1-covid14 ;

*set all to 0;
do i=1 to 14;
_covid(i) = 0;
end;

*set to 1 for each value of the COVID variable, ie COVID1=1, COVID10=1, COVID11=1 etc;
do i=1 to nwords;
	index = input(scan(covid, i), 8.);
	_covid(index) = 1;
end;

drop nwords index i;
run;

@mraposa1 wrote:

I have a dataset from a survey where one of the questions was select all that apply. When exported from Qualtrics to Excel, the variable is in this format:

Obs
Covid

1
1,10,11,12,13,14

2
1,12

There are 16 potential response options. I am stuck how to create binary variables for each response option without hardcoding everything in excel. I ultimately want to determine how many observations selected each response option.

Re: Select all that apply variable to binary variables

mraposa1 — Fri, 03 Jun 2022 00:50:33 GMT

Thank you so much! I appreciate it!

Re: Select all that apply variable to binary variables

Tom — Fri, 03 Jun 2022 01:35:14 GMT

You can also loop the other way. Loop over the codes 1 to 14 and check if they are in the list or not.

data binary;
  set have;
  array _covid covid1-covid14 ;
  do index=1 to 14 ;
     _covid[index] = 0 <  indexw(covid,cats(index),', ')  ;
  end;
  drop index;
run;