topic I need to create the subscript lower case letter n on the SGPLOT axis in SAS Software for Learning Community

I need to create the subscript lower case letter n on the SGPLOT axis

Yury2 — Mon, 17 Jul 2023 14:01:14 GMT

I need to create the subscript lower case letter n on the SGPLOT axis. I read online how
to do this using Unicode but it does not work. It displays blank square
instead of a subscript. There is no error or warning messages in the
log. I used the dataset from the SASHELP library so that anyone can ran the code. I am using SAS free server for academics. I am wondering if the problem is with the server rather than with the code itself. The code is below. Please, advise.

ods escapechar='~';
ODS GRAPHICS / ANTIALIASMAX=4100 ATTRPRIORITY=NONE ;
ODS PDF FILE="&reports.SGPLOT_with_subsript_n.pdf";

PROC SGPLOT DATA=SASHELP.CARS;
SCATTER X=LENGTH Y=Weight;
/* Use Unicode for subscript lowercase n */
YAXIS LABEL="W~{unicode '2099'x}"
labelattrs=(size=14pt family='Times New Roman Uni')
;
XAXIS LABEL="L~{unicode '2099'x}"
labelattrs=(size=14pt FAMILY="Times New Roman Uni")
;
RUN;

ODS PDF CLOSE;

Re: I need to create the subscript lower case letter n on the SGPLOT axis

PaigeMiller — Mon, 17 Jul 2023 14:09:37 GMT

See this example from @Ksharp

https://communities.sas.com/t5/Graphics-Programming/How-to-add-superscript-to-sgplot-labels-to-the-power-6/m-p/876426#M23796

Re: I need to create the subscript lower case letter n on the SGPLOT axis

Yury2 — Mon, 17 Jul 2023 15:46:21 GMT

Thank you for suggestions. Unfortunately, it does not work. More specifically, the superscript 6 as in your example works but subscript n (Unicode 2099) does not. I am including the code.

 
 data _anno; 
length label $ 200; 
 drawspace="layoutpercent"; function="text"; textweight="normal"; textsize=12;textcolor="black"; width=200; 
 x1=50; y1=2.5;label="XXXXX(*ESC*){unicode '2099'x}"; output; 
 x1=2.5;  y1=50;rotate=90;label="YYYY(*ESC*){sub '6'}"; output; 
 run; 
 
proc sgplot data=sashelp.class sganno=_anno noautolegend ;    
scatter x=weight y=height/group=sex datalabel=name;    
xaxis label=' '; 
yaxis label=' '; 
run;

Re: I need to create the subscript lower case letter n on the SGPLOT axis

Ksharp — Tue, 18 Jul 2023 11:37:05 GMT

/*There is no need to use unicode character 
if you are using macro %sganno ,just type in it*/

 data _anno; 
length label $ 200; 
 drawspace="layoutpercent"; function="text"; textweight="normal"; textsize=12;textcolor="black"; width=200; 
 x1=50; y1=2.5;label="XXXXX(*ESC*){sub 'n'}"; output; 
 x1=2.5;  y1=50;rotate=90;label="YYYY(*ESC*){sub 'n'}"; output; 
 run; 
 
proc sgplot data=sashelp.class sganno=_anno noautolegend ;    
scatter x=weight y=height/group=sex datalabel=name;    
xaxis label=' '; 
yaxis label=' '; 
run;

Re: I need to create the subscript lower case letter n on the SGPLOT axis

Yury2 — Tue, 18 Jul 2023 12:17:16 GMT

Thanks a lot. This worked!