topic How to remove last character in the string if it is a '+' in SAS Programming

How to remove last character in the string if it is a '+'

ahhh — Mon, 30 Oct 2017 04:29:41 GMT

Hi,

I have a variable 'name' like this -

data have;
input name $30. ;
datalines;
aaaaa+
bbb+aa+
dd+cc
fff+aa+dd+
gg+d
;
run;

I need the last character in the string to be removed only if it is a '+'. Some observations don't end in a '+' and those should be left as is. Also the '+' in other positions in the variable should be left as is, only if it is in the last position, it needs to be remove. How do I do this? Any advice is appreciated!

This is how I want it to look:

Name

aaaaa
bbb+aa
dd+cc
fff+aa+dd
gg+d

Thanks!

Re: How to remove last character in the string if it is a '+'

rajeshalwayswel — Mon, 30 Oct 2017 04:46:38 GMT

data have;
input name $30. ;
a=compress(name,' ','ka');
datalines;
aaaaa+
bbb+aa+
dd+cc
fff+aa+dd+
gg+d
;
run;

by using compress function with keep only alphabetics we can remove '+' from the given data

Re: How to remove last character in the string if it is a '+'

ahhh — Mon, 30 Oct 2017 04:55:37 GMT

Thanks! But, I would still like to keep the '+' in the middle. Only if the string ends with a '+' , only that '+' needs to be removed. Other '+'s should be left as is...

Re: How to remove last character in the string if it is a '+'

rajeshalwayswel — Mon, 30 Oct 2017 05:07:31 GMT

data have;
input name $30. ;
if substr(reverse(strip(name)),1,1)='+' then a=reverse(substr(reverse(strip(name)),2));
else a=name;
datalines;
aaaaa+
bbb+aa+
dd+cc
fff+aa+dd+
gg+d
;
run;

Re: How to remove last character in the string if it is a '+'

Kurt_Bremser — Mon, 30 Oct 2017 07:04:50 GMT

Alternative:

data want;
set have;
if substr(name,length(name),1) = '+' then name = substr(name,1,length(name)-1);
run;

Re: How to remove last character in the string if it is a '+'

Ksharp — Mon, 30 Oct 2017 12:58:16 GMT


data have;
input name $30. ;
want=prxchange('s/\++$//',1,strip(name));
datalines;
aaaaa+
bbb+aa+
dd+cc
fff+aa+dd+
gg+d
;
run;

Re: How to remove last character in the string if it is a '+'

ahhh — Mon, 30 Oct 2017 15:26:28 GMT

Thank you!

Re: How to remove last character in the string if it is a '+'

ahhh — Mon, 30 Oct 2017 15:27:09 GMT

Thank you!

Re: How to remove last character in the string if it is a '+'

ahhh — Mon, 30 Oct 2017 15:27:56 GMT

Thanks everyone! it worked!

Re: How to remove last character in the string if it is a '+'

rajeshalwayswel — Mon, 30 Oct 2017 21:06:10 GMT

Hi,

I'm wondering how it works can you please explain

prxchange function.

Thanks,

Rajesh