topic Return the word after and before a keyword in SAS Programming

Return the word after and before a keyword

camfarrell25 — Fri, 27 Oct 2017 19:42:12 GMT

Hello,

I'm looking to create a variable that contains the word directly before and directly after a keyword.

For example, if the keyword I would like to search for is "Apple" then

The apple is green and red ==> "the apple is"

I love to eat a lot of apples ==> "of apples"

I like orange juice ==> ""

And I would like to apply that to multiple keywords.

Thanks!

Re: Return the word after and before a keyword

collinelliot — Fri, 27 Oct 2017 19:56:03 GMT

How many keywords are you talking about? The below works for the example you provided, but it will certainly have to be modified to address all of your data.


data want;
    input @1 text $40.;

    prxExp = prxparse('/(\w{0,})(\sapples?\s)(\w{0,})/i');
    if prxmatch(prxExp, text) > 0 then do;
        want_var = prxposn(prxExp, 0, text);
    end;
datalines;
The apple is green and red
I love to eat a lot of apples
I like orange juice
;

Re: Return the word after and before a keyword

camfarrell25 — Fri, 27 Oct 2017 19:58:41 GMT

I have 5 keywords.

Thanks for your help!!
CF

Re: Return the word after and before a keyword

collinelliot — Fri, 27 Oct 2017 20:21:10 GMT

Five is small enough that you could probably just add them to the example I gave you.

Re: Return the word after and before a keyword

collinelliot — Fri, 27 Oct 2017 20:25:37 GMT

I'm sure there's a more elegant way, but if this meets your needs...

prxExp = prxparse('/(\w{0,})(\sapples?\s|\skeyword2\s|\skeyword3\s)(\w{0,})/i');

Re: Return the word after and before a keyword

mkeintz — Fri, 27 Oct 2017 20:57:55 GMT

Can a phrase have more than 1 keyword? If so, what do you want to do?

Re: Return the word after and before a keyword

PGStats — Sat, 28 Oct 2017 04:08:37 GMT

I would go for:

data want;
if not prxId then 
    prxId + prxparse("/(\w+\s+)?\b(apples?|cherr(y|ies)|bananas?)\b(\s+\w+)?/io");

infile datalines truncover;
input text $100.;
length extract $100;

start = 1; stop = -1;
call prxnext(prxId, start, stop, text, pos, len);
if pos = 0 then output;
do while (pos > 0);
    extract = substr(text, pos, len);
    output;
    call prxnext(prxId, start, stop, text, pos, len);
    end;
keep text extract;
datalines;
The apple is green and red
I love to eat a lot of apples
The  apple is green and red
I said "Apple".
I love to eat pineapples
APPLES, ORANGES, and BANANAS
I like orange juice
;

proc print; by text notsorted; id text; run;

Re: Return the word after and before a keyword

Ksharp — Sun, 29 Oct 2017 12:23:54 GMT


data want;
input text $40.;
do i=1 to countw(text,' ');
 temp=scan(text,i,' '); 
 if find(temp,'apple','i') then do;
   want=catx(' ',scan(text,i-1,' '),temp,scan(text,i+1,' '));
 end;
end;
drop i temp;
datalines;
The apple is green and red
I love to eat a lot of apples
I like orange juice
;

Re: Return the word after and before a keyword

camfarrell25 — Mon, 30 Oct 2017 11:04:37 GMT

I found a variation that works well - in the case that there's a period, comma or other non-text character, it also identifies it:

prxExp1 = prxparse('/(\w{0,})(\W{1,})(word1|word2|word3|word4|word5)(\W{1,})(\w{0,})/i');
if prxmatch(prxExp1, text) > 0 then do;
string = prxposn(prxExp1, 0, text)