topic Re: sas base and proc sql code for following question plz help in SAS Programming

sas base and proc sql code for following question plz help

ganeshmule — Wed, 25 Oct 2017 18:43:02 GMT

data have;

infile datalines missover dsd;

input name $ country $ salary;

datalines;

ganesh,, 40000

ganesh,india,

;

run;

output data set should be like as under

name country salary

ganesh india 40000

thanks in advance

Re: sas base and proc sql code for following question plz help

Reeza — Wed, 25 Oct 2017 19:27:24 GMT

UPDATE statement is what you want/need.

Re: sas base and proc sql code for following question plz help

PGStats — Thu, 26 Oct 2017 04:21:27 GMT

Use the self-update trick where every non-missing variable overwrites the previous value within a by group.

data have;
infile datalines missover dsd;
input name $ country $ salary;
datalines;
ganesh,, 40000
ganesh,india,  
Smith,USA,
Smith,,100000 
;

proc sort data=have; by name; run;

data want;
update have(obs=0) have;
by name;
run;

proc print; run;

Re: sas base and proc sql code for following question plz help

PGStats — Thu, 26 Oct 2017 04:29:38 GMT

To do this with SQL is not efficient:


proc sql;
select * 
from 
    (select unique name from have) 
    natural left join
    (select name, country from have where country is not missing)
    natural left join
    (select name, salary from have where salary is not missing);
quit;