topic Re: Selecting several first and last values of variables in SAS Programming

Selecting several first and last values of variables

DmytroYermak — Wed, 11 Oct 2017 11:51:32 GMT

Hi all,

Please advise how to manage the following case. I have to select the values FLAG1 and FLAG2 from the first line of the group and FLAG3 and IDENT from the last line. Could you please advise a compact algorythm? The sample code is attached.

Thank you!

data test;
	infile datalines dlm='/';
	input FLAG1 : $1. FLAG2 : $1. FLAG3 : $1. IDENT : $7.;
datalines;
Y	/	N	/		/	ABC-101
N	/	N	/		/	ABC-101
N	/	N	/	Y	/	ABC-101
Y	/	N	/		/	ABC-102
N	/	N	/		/	ABC-102
N	/	N	/		/	ABC-102
N	/	N	/		/	ABC-102
N	/	N	/		/	ABC-103
N	/	N	/		/	ABC-103
N	/	N	/		/	ABC-103
N	/	N	/	N	/	ABC-103

;
run;

Re: Selecting several first and last values of variables

gamotte — Wed, 11 Oct 2017 12:07:33 GMT

Hello,

data want;
	set test;
	by IDENT;
	array FLAGS(2) $1. _TEMPORARY_;

	if first.IDENT then do;
		FLAGS(1)=FLAG1;
		FLAGS(2)=FLAG2;
	end;

	if last.IDENT then do;
		FLAG1=FLAGS(1);
		FLAG2=FLAGS(2);
		output;
	end;
run;

Re: Selecting several first and last values of variables

DmytroYermak — Wed, 11 Oct 2017 13:10:30 GMT

It has worked! Thank you very much!