topic Re: How to compare 2 datasets observations and execute a list of command based on the result in SAS Programming

How to compare 2 datasets observations and execute a list of command based on the result

krisraa — Thu, 05 Oct 2017 00:42:58 GMT

I have 2 data sets (Current and Prev month).

I need to compare the 2 datasets no. of observations and if the current month data set has more no. of records then I need to run or call a macro?

How do I achieve that?

Re: How to compare 2 datasets observations and execute a list of command based on the result

ShiroAmada — Thu, 05 Oct 2017 01:21:09 GMT

Try this....

proc sql noprint;
  select nobs into: curr from dictionary.tables
  where upcase(libname)="MYLIB" and upcase(memname)='MY_CURR';

  select nobs into: PREV from dictionary.tables
  where upcase(libname)="MYLIB" and upcase(memname)='MY_PREV';
QUIT;

%macro HasMore;
%if %eval(&prev<curr) %then %do;
  %MyMacro;
%end;

%mend

%HasMore;

Hope this helps.

Re: How to compare 2 datasets observations and execute a list of command based on the result

ChrisNZ — Thu, 05 Oct 2017 03:53:51 GMT

Like this?

data _null_;
  if NOBS1 ne NOBS2 then call execute('%mymacro;');
  set TABLE1 nobs=NOBS1;
  set TABLE2 nobs=NOBS2;
  stop;
run;

Simple since there is no macro language, and fast since we don't use the dictionary.

Re: How to compare 2 datasets observations and execute a list of command based on the result

krisraa — Thu, 05 Oct 2017 18:54:24 GMT

Thanks Chris it did the job for me....

Any specific reason why the if logic before reading the data sets?

Re: How to compare 2 datasets observations and execute a list of command based on the result

ChrisNZ — Fri, 06 Oct 2017 02:03:39 GMT

If you put it after the SET statements and one of the data sets is empty, it will never be executed.

Re: How to compare 2 datasets observations and execute a list of command based on the result

SAS_inquisitive — Fri, 06 Oct 2017 02:23:56 GMT

nobs are obtained during compile time so they can be used before SET statement.

Re: How to compare 2 datasets observations and execute a list of command based on the result

ali_jooan — Fri, 06 Oct 2017 06:01:03 GMT

start using Proc Compare ..