topic Re: Assign the macro result of each obs to a new variable in datastep in SAS Programming

Assign the macro result of each obs to a new variable in datastep

Lochen — Wed, 04 Oct 2017 16:44:48 GMT

Hello,

I created a macro to calculate two values based on input and assign them to 2 global macro variables _obs and _rate. But right now I have some problems when use it in a data step.

My data step code is the following:

data d2;
set d1;
call execute('%nrstr(%incidence_sys(_var1="'||Type||'"))');
obs = &_obs;
rate = &_rate;
run;

The macro is %incidence_sys. I want to use each 'Type' of observation as my macro input. Then the macro computes and saves those two global macro variables: _obs and _rate. Next I need to assign them to two variables of each row in dataset. But the code seems run the macro through all rows first then assigns the last _obs and _rate back to all rows. I set my macro to put some results, it did calculate values based on each row.

My data set is like

ID Type ...

1 A

2 B

3 B

4 C

I expect the result is like

ID Type obs rate...

1 A 10 0.11

2 B 12 0.51

3 B 11 0.41

4 C 5 0.3

But currently my result is

ID Type obs rate...

1 A 5 0.3

2 B 5 0.3

3 B 5 0.3

4 C 5 0.3

Re: Assign the macro result of each obs to a new variable in datastep

Reeza — Wed, 04 Oct 2017 16:56:53 GMT

Order of operations.

Call Execute executes AFTER the data step is finished, so the variables don't exist.

Is PROC FCMP an option instead, since it can return values, like a function?

Re: Assign the macro result of each obs to a new variable in datastep

PaigeMiller — Wed, 04 Oct 2017 16:57:56 GMT

One problem is that CALL EXECUTE doesn't do anything until a step boundary, in other words it doesn't set values in the present data step or make macro variables available in the present data step.

Of course, there may be other problems as well since we can't see your data and we don't know what %incidence_sys does.

Re: Assign the macro result of each obs to a new variable in datastep

Lochen — Wed, 04 Oct 2017 17:04:19 GMT

Thanks, Reeza.

My macro does return values. But it includes some SQL procedures.

Re: Assign the macro result of each obs to a new variable in datastep

Astounding — Wed, 04 Oct 2017 17:27:21 GMT

To embellish upon what @PaigeMiller said, you can't run PROC SQL in the middle of a DATA step. It doesn't matter whether you hard-code the PROC SQL, generate it with macro language, or use CALL EXECUTE. PROC SQL cannot be embedded within a DATA step.

You have already provided some sample inputs. If you were to describe your intentions -- how the inputs should be used to calculate the outputs -- there are probably other ways to get there.

Re: Assign the macro result of each obs to a new variable in datastep

Kurt_Bremser — Wed, 04 Oct 2017 17:48:44 GMT

Macro variables are resolved before the data step is compiled (and then run), while code included in call execute executes after the current step has finished, so if you expect the macro incidence_sys to set &obs and &rate, they're actually two execution stages apart.

Re: Assign the macro result of each obs to a new variable in datastep

Ksharp — Thu, 05 Oct 2017 07:08:56 GMT

Maybe you want function DOSUBL().

%macro xx(var1=);
%global a ;
%if &var1=A %then %let a=10;
 %else %if &var1=B %then %let a=12;
   %else %if &var1=C %then %let a=18;
%mend;

data have;
input ID    Type$;
cards;
1         A
2         B
3         B
4         C
;
run;
data want;
 set have;
 rc=dosubl(cats('%xx(var1=',type,')'));
 rate=symgetn('a');
 run;

Re: Assign the macro result of each obs to a new variable in datastep

Lochen — Fri, 06 Oct 2017 21:20:50 GMT

Thanks Ksharp.

It works and gives me what I want exactly.