topic Re: renaming a variable inside a macro in SAS Programming

renaming a variable inside a macro

ilikesas — Sun, 01 Oct 2017 17:35:08 GMT

Hi,

I have the following macro:

%macro varz(variable);
data qc2;
set qc;
keep gvkey fyear &variable;
rename &variable=&variable.._qc;
run;
%mend;

%varz(sales);

So here I want to create a data table qc2 which will include the variables gvkey, fyear and sales from the original table qc, and then rename sales to sales_qc, but it is this renaming part which causes errors (if it is omitted then the macro works).

Thank you

Re: renaming a variable inside a macro

error_prone — Sun, 01 Oct 2017 17:52:27 GMT

Don't use a datastep to rename a variable, use proc datasets instead, there is no need to do a full iteration, when you just want to change metadata. And: why do you want a macro?

To solve the error in your code, reduce the number of dots between &variable and _qc to one.

Re: renaming a variable inside a macro

ilikesas — Mon, 02 Oct 2017 00:06:21 GMT

I have 2 datasets: qc and cc, and there are variables with identical names in both datasets. I just wanted a quick way to compare the variables from the datasets. Here is the full code:

%macro varz(variable);
data qc2;
set qc;
keep gvkey fyear &variable;
rename &variable=&variable._qc;
run;

data cc2;
set cc;
keep gvkey fyear &variable;
rename &variable=&variable._cc;
run;

data want;
merge qc2 cc2;
by gvkey fyear;
run;

data want;
set want;
diff = &variable._qc - &variable._cc;
run;

proc means data=want;
run;

%mend;

%varz(sale);

Re: renaming a variable inside a macro

Patrick — Mon, 02 Oct 2017 01:22:40 GMT

@ilikesas

The following might give you the idea how you could go about this.

data work.demo;
  set sashelp.class;
run;

proc sql noprint;
  select
    cats(name,'= demo_',name) 
      into :rename_list separated by ' '
  from dictionary.columns
  where libname='WORK' and memname='DEMO' and upcase(name) not in ('NAME','HEIGHT')
  ;
quit;

proc datasets lib=work nolist;
  modify demo;
    rename &rename_list;
  run;
quit;

proc contents data=demo;
run;quit;

Alternatively consider using Proc Compare.

Re: renaming a variable inside a macro

error_prone — Mon, 02 Oct 2017 05:26:36 GMT

Automatically renaming variables will work only if you are 100% sure, that each variables name with the appended postfix is shorter than 32 chars.

Depending on what you want to do with the result of the comparison, using proc compare can be the easier solution.