topic Re: Sorting and assigning 'Sequence Number within each group' in one (minimum) steps in SAS Programming

Sorting and assigning 'Sequence Number within each group' in one (minimum) steps

DmytroYermak — Wed, 20 Sep 2017 12:29:12 GMT

Hi all,

I have the following

How is it possible to sort the dataset by 2 variables and assign a Sequence Number in one step?

data test;
	length division group $2.;
	infile datalines;
	input division group;
datalines;
a	t1
b	m2
a	t1
b	m2
a	t2
a	t2
a	t2
b	m2
a	t1
b	m1
b	m1
a	t2


;
run;

proc print data=test; run;

I need the following output:

Re: Sorting and assigning 'Sequence Number within each group' in one (minimum) steps

PeterClemmensen — Wed, 20 Sep 2017 12:38:14 GMT

Like this?

data test;
input division$ group$;
datalines;
a t1
b m2
a t1
b m2
a t2
a t2
a t2
b m2
a t1
b m1
b m1
a t2
;

proc sort data=test;
	by division group;
run;

data want;
	set test;
	by division group;
	Seq+1;
	if first.group then Seq=1;
run;

Re: Sorting and assigning 'Sequence Number within each group' in one (minimum) steps

Haikuo — Wed, 20 Sep 2017 12:43:24 GMT

There are many ways to do the sorting in SAS, for example

proc sort data=test out=want;
by division group;
run;

Or:

proc sql;
create table want as
select * from test
order by division, group
;
quit;

Also, Hash object can also do sort, but it will be overdone for your purpose.

Re: Sorting and assigning 'Sequence Number within each group' in one (minimum) steps

DmytroYermak — Wed, 20 Sep 2017 12:43:59 GMT

Thank you for the quick help!

Re: Sorting and assigning 'Sequence Number within each group' in one (minimum) steps

PeterClemmensen — Wed, 20 Sep 2017 12:52:36 GMT

Anytime, glad to help 🙂