topic Re: UPPERCASE AND LOWERCASE in SAS Programming

UPPERCASE AND LOWERCASE

WPH — Tue, 19 Sep 2017 12:40:28 GMT

Hi all,

I am quite new here as SAS user and i need your help.

Is there any code to identify the variable, if its lowercase or uppercase? Without looking into sashelp.vcolumn?

My goal is, i want to make a list which variable that already uppercase and which one are not.

btw i use SAS enterprise guide

Thank you for your help

WPH

Re: UPPERCASE AND LOWERCASE

PeterClemmensen — Tue, 19 Sep 2017 12:47:56 GMT

Perhaps something like this?

Compare the variable to its upcase equivalent and output accordingly.

data have;
input charvar$;
datalines;
Hello
HELLO
;

data Upcase notUpcase;
	set have;
	if upcase(charvar)=charvar then output Upcase;
	else output notUpcase;
run;

Re: UPPERCASE AND LOWERCASE

Haikuo — Tue, 19 Sep 2017 13:14:27 GMT

Not entirely sure about your intention, is it value of the variable(see @PeterClemmensen's solution), or is it the name of the variable, since you mentioned metadata 'vcolumns'. SAS, in operation, does not care the case of the variables, however, you can still put it out as being shown below:

data want;
	set sashelp.class(keep=age); /*Age came in as Proper case variable*/
	AGE_UP=age;/*upper case variable name*/
	age_low=age;/*lower case variable name*/
	array _age age:;
	array po proper upper lower;

	do over _age;
	/*the show the position of first lower case in the varialble name*/
		po=anylower(vname(_age));/*you can also use anyupper() for this purpose*/
	end;
run;

Re: UPPERCASE AND LOWERCASE

WPH — Tue, 19 Sep 2017 13:21:59 GMT

Hi Haikuo and Draycut

Thank you for your response.

My intention was the name of the variable. I have created some macro, could you please take a look. What do you think?

%MACRO check_upcase;
PROC SQL;
CREATE TABLE check_01 AS
SELECT *
FROM sashelp.vcolumn
WHERE memname EQ 'ADAE' AND libname EQ 'DERIVED';
QUIT;
DATA notupcase;
set check_01;
IF upcase(name)NE name THEN OUTPUT notupcase;
RUN;
%IF obs. >0 %THEN %DO;
%PUT %SYSFUNC( CATT(WARNING: Please check the dataset check_upcase. Some variable its not UPCASE. )) ;
%END;
%MEND check_upcase;
%check_upcase;

Re: UPPERCASE AND LOWERCASE

Haikuo — Tue, 19 Sep 2017 16:53:42 GMT

Not sure why you need a macro, but your code is unnecessarily complicated, you can wrap up the following code in a macro:

data _null_;
set sashelp.vcolumn;
WHERE memname EQ 'ADAE' AND libname EQ 'DERIVED';
IF upcase(name)NE name 
then put "WARNING: Please check the dataset check_upcase. Some variable its not UPCASE.";
run;

Re: UPPERCASE AND LOWERCASE

PeterClemmensen — Tue, 19 Sep 2017 13:53:25 GMT

Ah ok sorry, did not catch that 🙂

Re: UPPERCASE AND LOWERCASE

ShiroAmada — Tue, 19 Sep 2017 14:03:53 GMT

I think something is wrong with this statement

"%IF obs. >0 %THEN %DO;"

Is OBS a dataset variable or a macro variable?

Re: UPPERCASE AND LOWERCASE

WPH — Tue, 19 Sep 2017 15:25:59 GMT

Hi Haikuo,

I try to wrap up your code in the macro, please see

%MACRO check_upcase;
data _null_;
set sashelp.vcolumn;
WHERE memname EQ 'ADAE' AND libname EQ 'DERIVED';
%IF upcase(name)NE name %then %DO;
%put %SYSFUNC( CATT( WARNING: Please check the dataset check_upcase Some variable its not UPCASE));
%END;
%MEND check_upcase;
%check_upcase;

Unfortunately come this error message, could you help me please

The SAS System

NOTE: Writing TAGSETS.SASREPORT13(EGSR) Body file: EGSR
ERROR: Required operator not found in expression: upcase(name)NE name
ERROR: The macro CHECK_UPCASE will stop executing.
39 ;*';*";*/;quit;run;
____
180

ERROR 180-322: Statement is not valid or it is used out of proper order.

NOTE: The SAS System stopped processing this step because of errors.
NOTE: DATA statement used (Total process time):
real time 0.01 seconds
cpu time 0.01 seconds

Re: UPPERCASE AND LOWERCASE

Haikuo — Tue, 19 Sep 2017 16:53:01 GMT

You are a fresh SAS user, I suggest you progress one step at a time. I would try to learn how to write plain SAS code as the first step, then I will learn how to delivery it (Macro). As a rule of thumb, advoid mixing SAS code and Macro like you did. Here, when I say 'wrap my code', I mean 'wrap my code' as is, not 'modify my code then wrap it' :),

%MACRO check_upcase;
data _null_;
set sashelp.vcolumn;
WHERE memname EQ 'ADAE' AND libname EQ 'DERIVED';
IF upcase(name)NE name 
then put "WARNING: Please check the dataset check_upcase. Some variable its not UPCASE.";
run;
%MEND check_upcase;
%check_upcase;