topic Re: Renaming a dataset during a proc datasets in SAS Programming

Renaming a dataset during a proc datasets

DmytroYermak — Wed, 13 Sep 2017 11:30:33 GMT

Hi all,

Is it possible to copy datasets and rename them simultaneously? I have coded it but the prog failed (.

proc datasets library=rawdata nolist;
copy out=work;
change work.ex_test=ex work.lb_test=lb work.suppex_test=suppex work.sv_text=sv work.tv_test=tv;
run;

Thank you!

Re: Renaming a dataset during a proc datasets

alexal — Wed, 13 Sep 2017 11:44:55 GMT

@DmytroYermak,

I would suggest using PROC SQL, here is an example:

proc sql noprint; 
  create table work.test as select * from sashelp.cars; 
run; 
quit;

Re: Renaming a dataset during a proc datasets

RW9 — Wed, 13 Sep 2017 11:56:51 GMT

Why do you have SDTM domains called _test in the first place? Seems like that is your problem. Anyways, no, you need to generate the code:

data _null_;
  set sashelp.vtable (where=(libname="WORK"));
  call execute('data work.'||strip(tranwrd(memname,"_TEST",""))||'; set work.'||strip(memname)||'; run;');
run;

Re: Renaming a dataset during a proc datasets

DmytroYermak — Wed, 13 Sep 2017 11:56:54 GMT

Thank you. Is it possible to do for several datasets in one step?

Re: Renaming a dataset during a proc datasets

alexal — Wed, 13 Sep 2017 12:13:14 GMT

@DmytroYermak,

Sure,

proc sql noprint; 
  create table work.test as select * from sashelp.cars; 
  create table work.test2 as select * from sashelp.baseball;
run; 
quit; 
proc print data=test; run;
proc print data=test2; run;

Re: Renaming a dataset during a proc datasets

Ksharp — Wed, 13 Sep 2017 13:01:55 GMT

Once you copy all the tables into a library like WORK.

It is easy to rename the table name.

data ex_test;
 set sashelp.class;
run;
data suppex_test;
 set sashelp.class;
run;


data _null_;
 set sashelp.vmember(where=(libname='WORK')) end=last;
 if _n_=1 then call execute('proc datasets library=work nolist nodetails;change ');
 call execute(catt(memname,'=',scan(memname,1,'_')));
 if last then call execute(';quit;');
run;

Re: Renaming a dataset during a proc datasets

DmytroYermak — Wed, 13 Sep 2017 13:49:58 GMT

Actually, I tried several times and here it is the result. It works but is it correct?

proc datasets library=rawdata nolist; 
    copy out=work;
run;
proc datasets nolist; 
    change ex_test=ex lb_test=lb suppex_test=suppex sv_test=sv tv_test=tv;
run;

Re: Renaming a dataset during a proc datasets

Ksharp — Wed, 13 Sep 2017 13:32:20 GMT

Yes. I think so.

proc datasets library=work nolist;  
   change ex_test=ex
 lb_test=lb 
suppex_test=suppex 
sv_test=sv 
tv_test=tv;
quit;

Re: Renaming a dataset during a proc datasets

Tom — Wed, 13 Sep 2017 13:53:35 GMT

@DmytroYermak wrote:

Actually, I tried several times and here it is the result. It works but is it correct?
proc datasets library=rawdata nolist; 
    copy out=work;
run;
proc datasets nolist; 
    change ex_test=ex lb_test=lb suppex_test=suppex sv_test=sv tv_test=tv;
run;

That will work, but there may be side effects.

For example if there is already a table named WORK.EX_TEST it will be over written by the COPY step.