topic Finding group of consecutive flags in SAS Programming

Finding group of consecutive flags

anu1999 — Mon, 11 Sep 2017 17:50:00 GMT

Hi All,

I am trying to implement a logic but not able to achieve the right output. I would appreciate any help.

I have a dataset which has columns: student and flag. I want to calculate consecutive_flag column which will create group of flags within the student group. an example below:

student	flag	consective_flag
1	0	0
1	0	0
1	0	0
1	1	1
1	1	1
1	1	1
1	0	0
1	1	2
1	1	2
1	0	0
1	0	0
1	1	3
1	1	3
2	1	1
2	1	1
2	1	1
2	1	1
2	0	0
2	1	2
2	0	0
2	0	0
2	1	3
2	1	3

Re: Finding group of consecutive flags

novinosrin — Mon, 11 Sep 2017 18:00:33 GMT

data have(drop=consective_flag);

input student flag consective_flag;

datalines;

1 0 0

1 1 1

1 0 0

1 1 2

1 0 0

1 1 3

2 1 1

2 0 0

2 1 2

2 0 0

2 1 3

;

data want;

set have;

by student flag notsorted;

retain t consective_flag ;

if first.student then call missing(consective_flag,t);

if first.flag and not flag then consective_flag=flag;

else if first.flag and flag then do;

t+flag;

consective_flag=t;

end;

drop t;

run;

Re: Finding group of consecutive flags

anu1999 — Mon, 11 Sep 2017 18:07:05 GMT

appreciate it so much! it works perfect.

Re: Finding group of consecutive flags

Ksharp — Wed, 13 Sep 2017 14:29:18 GMT

data have(drop=consective_flag);
input student   flag consective_flag;
datalines;
1    0    0
1    0    0
1    0    0
1    1    1
1    1    1
1    1    1
1    0    0
1    1    2
1    1    2
1    0    0
1    0    0
1    1    3
1    1    3
2    1    1
2    1    1
2    1    1
2    1    1
2    0    0
2    1    2
2    0    0
2    0    0
2    1    3
2    1    3
;
data want;
 set have;
 by student flag notsorted;
 if first.student then count=0;
 if first.flag and flag=1 then count+1;
 if flag=1 then want=count;
  else want=0;
 drop count;
run;

Re: Finding group of consecutive flags

anu1999 — Wed, 13 Sep 2017 15:01:50 GMT

Another great way. Thanks, this works too.