topic I want to create the separate datasets for each location, when number of locations are not specified in SAS Programming

I want to create the separate datasets for each location, when number of locations are not specified

Kusuma001 — Sat, 09 Sep 2017 06:40:34 GMT

Question:

if user dont know how many locations are there in input, then how can we write a code in SAS

Task :

data one;

input emp_id name$ loc$;

datalines;

1 srinivas bang

2 sudhakar bang

3 qqqq hyd

4 hhhh hyd

5 bhanu mumbai

6 jjjjj mumbai

;

run;

Solution:;

DATA Bang;

set one(where=(loc='bang'));

run;

DATA Hyd;

set one(where=(loc='hyd'));

run;

DATA Mumbai;

set one(where=(loc='mumbai'));

run;

Re: I want to create the separate datasets for each location, when number of locations are not speci

Reeza — Sat, 09 Sep 2017 11:55:54 GMT

If you search 'split data into subsets' you'll find many solutions. Note that this is rarely recommended in SAS

http://blogs.sas.com/content/sasdummy/2015/01/26/how-to-split-one-data-set-into-many/

Re: I want to create the separate datasets for each location, when number of locations are not speci

PeterClemmensen — Sun, 17 Sep 2017 15:42:56 GMT

If you dont know how any locations are in your data step, this HASH object solution works well.

data one;
input emp_id  name$ loc$;
datalines;
1 srinivas bang
2 sudhakar bang
3 qqqq hyd
4 hhhh hyd
5 bhanu mumbai
6 jjjjj mumbai
;

proc sort data=one;
   by loc;
run;

data _null_;
   if _n_=1 then do;
   if 0 then set one;
   declare hash h(dataset:"one(obs=0)", multidata:'y');
      h.definekey(all:'y');
      h.definedata(all:'y');
      h.definedone();
   end;
   do until(last.loc);
      set one;
      by loc;
      h.add();
   end;
   h.output(dataset:loc);
   h.clear();
run;

http://sasnrd.com/split-data-by-group/

Re: I want to create the separate datasets for each location, when number of locations are not speci

Kusuma001 — Sat, 09 Sep 2017 12:35:24 GMT

It works!! Thank you so much 🙂