topic input without knowing length in SAS Programming

input without knowing length

FP12 — Tue, 22 Aug 2017 11:40:35 GMT

Hi,

I want to convert a character A to numberic B

I use the input() function. But you can only use it if you know the length of A.

A = input(B,8.2)

But I don't know if it is 8.2 or whatever.

Do you know how I can manage it?

Re: input without knowing length

Kurt_Bremser — Tue, 22 Aug 2017 11:56:00 GMT

Use the best. format:

data test;
input b :$32.;
a = input(b,best32.);
format a best32.;
cards;
123456.78
12345678912.22
1.12345678905
3.14159265358979323846
;
run;

proc print data=test noobs;
run;

Result:

b                                                        a

123456.78                                        123456.78
12345678912.22                              12345678912.22
1.12345678905                                1.12345678905
3.14159265358979323846                    3.14159265358979

Note how the Pi example shows the limits of numeric precision in SAS.

Re: input without knowing length

RW9 — Tue, 22 Aug 2017 12:09:00 GMT

I would question why you do not know your data, seeing as that is the fundamental basis for programming with? What if it contains non-numerics, or signs/percentages, what format should the output variable have etc.

Re: input without knowing length

Oligolas — Tue, 22 Aug 2017 13:00:44 GMT

Hi,

a pragmatic approach could be to perform a reconversion check and issue warnings to your log in case of conversion failure.

Something like that:

if strip(put(a,best32.)) ne b then put 'W' 'ARNING: conversion issue please check' a= b=;

Re: input without knowing length

andreas_lds — Tue, 22 Aug 2017 13:11:32 GMT

Another way to verify that the char var has been converted successfully, uses the double ? modifier in the input function. Thanks to @Kurt_Bremser for provding example data 😉

data test;
input b :$32.;
a = input(b, ?? best32.);
if missing(a) and not missing(b) then put 'WARNING: Failed to convert ' b 'Check obs' _n_= ;
format a best32.;
cards;
123456.78
12345678912.22
1.12345678905
bob
3.14159265358979323846
;
run;

proc print data=test noobs;
run;