topic Re: Reshape Wide Field to Long in SAS Programming

Reshape Wide Field to Long

angeliquec — Wed, 16 Aug 2017 06:15:42 GMT

Hi,

I need help to produce the WANT dataset from my HAVE dataset.

data want;
input num code $;
cards;
1 A
1 B
2 C
2 D
;
run;

data HAVE;
input num code $;
cards;
1 A,B
2 C,D
;
run;

Re: Reshape Wide Field to Long

Kurt_Bremser — Wed, 16 Aug 2017 06:39:16 GMT

With a data step and by group processing:

data have;
input num code $;
cards;
1 A
1 B
2 C
2 D
;
run;

data want;
set have (rename=(code=_code));
by num;
retain code "              "; * make long enough to hold all values;
if first.num then code = '';
code = catx(',',code,_code);
if last.num then output;
drop _code;
run;

proc print data=want noobs;
run;

Result:

num    code

 1     A,B 
 2     C,D

Correct order of dataset have by num is required.

Re: Reshape Wide Field to Long

user24feb — Wed, 16 Aug 2017 08:51:23 GMT

Another possible solution:

data have; 
input num code $;
cards;
1 A,B
2 C,D
;
run;

Data Want;
  Set have;
  Col_1 = Scan(code, 1, ",");
  Col_2 = Scan(code, 2, ",");
  Drop code;
Run;

Proc Transpose Data = Want 
		       Out = Want (Rename=(Col1=code) Drop=_NAME_);
  By num;
  Var Col_1 Col_2; 
Run;

Re: Reshape Wide Field to Long

error_prone — Wed, 16 Aug 2017 19:51:52 GMT

No need to use proc transpose. A loop with an output-statement will do:

data want;
set have;
fullCode = code;
do i = 1 to countw(fullCode, ",");
code = scan(fullCode, i, ",");
output;
end;
drop i fullCode;
run;