topic Re: Converting a numeric, non-integer year value to a SAS date in SAS Programming

Converting a numeric, non-integer year value to a SAS date

jdgriffin — Mon, 07 Aug 2017 13:27:20 GMT

I am working with a small dataset (see attached) that has time coded into fractional years. For example: 1990.1456, 1991.3568, 1991.5689...

Is there an INFORMAT that would allow me to read this variable in as a SAS date?

Thank you for any help you can offer.

-John

Re: Converting a numeric, non-integer year value to a SAS date

Kurt_Bremser — Mon, 07 Aug 2017 13:34:59 GMT

Try this:

data want;
input dateval;
dateval = round((dateval - 1960) * 365.2425,1);
format dateval yymmddd10.;
cards;
1990.1456
1991.3568
1991.5689
run;

Re: Converting a numeric, non-integer year value to a SAS date

mkeintz — Mon, 07 Aug 2017 13:58:31 GMT

There is no such informat.

However, you could calculate the date value (or is it really a datetime value?), by

Extract the year portion, i.e. the integer
Take the decimal portion and determine the corresponding datetime and multply by 24*60*60*(365 or 366) to get number of seconds into the year if you want date-time values.

data want;
  set have;
  year=floor(time);

  /* Get number of seconds in the year, accomodating leap years */
  secondsinyear=24*60*60*intck('day',mdy(1,1,year),mdy(1,1,year+1));

  datetimevalue=dhms(mdy(1,1,year),0,0,0) +
                secondsinyear*mod(time,1);

  datevalue=datepart(datetimevalue);
  format datetimevalue datetime20. datevalue date9.;
run;

Re: Converting a numeric, non-integer year value to a SAS date

jdgriffin — Mon, 07 Aug 2017 14:56:32 GMT

Thank you for the reply. So that I am understanding correctly, I am basically calculating the non-integer difference in years between my date and the SAS reference date, then converting it to integer days?

This is straight forward. I appreciate it.

Re: Converting a numeric, non-integer year value to a SAS date

jdgriffin — Mon, 07 Aug 2017 14:58:00 GMT

Thanks for the reply. I suppose you are correct that it could be considered a datetime given its level of accuracy. I'll be sure to give this a try as well.