topic Re: Rename in SAS Programming

Rename

SASPhile — Thu, 21 Jan 2010 19:31:37 GMT

Whats wrong with the code below to rename all the varibles to F1 to F16?

%maCRO rename;
data national_temp_v2;
set national_temp_v1;
array fields(*) ndc_code--Dr__DEA;
%do i=1 %to 16;
rename fields(i)=F&i.;
%end;
run;
%mend rename;
%rename;

Re: Rename

data_null__ — Thu, 21 Jan 2010 19:48:28 GMT

You can't use arrays and rename in that way. You might do it this way.

[pre]
*Create Test data;
data test;
if 0 then set sashelp.air;
length ndc_code $1;
if 0 then set sashelp.class sashelp.shoes;
length Dr__DEA 8;
call missing(of _all_);
stop;
run;
proc contents order=varnum;
run;

*Rename a range of variables to an enumerated list;
proc transpose data=test(obs=0) out=vars;
var ndc_code--Dr__DEA;
run;

data vars;
set vars;
length new $32;
new = cats('F',_n_);
run;
proc sql noprint;
select catx('=',_name_,new) into :rename separated by ' '
from vars;
quit;
run;
proc datasets;
modify test;
rename &rename;
run;
contents data=test order=varnum;
run;
quit;
[/pre]

Re: Rename

abdullala — Thu, 21 Jan 2010 19:50:17 GMT

1. if there are different data types in these variables array will not work.
2. the do loop in the data step should not use %, i.e. this is not a macro level loop.

what messages do you get from the log?

Re: Rename

abdullala — Thu, 21 Jan 2010 19:54:45 GMT

or you may simply create new variables F1 -- F16 in the loop, as
array f (*) f1 - f16;

...

do i=1 to dim(f);
f(i)=field(i);
end;

then delete the original fields.

Re: Rename

sbb — Thu, 21 Jan 2010 20:08:48 GMT

You are attempting to mix MACRO language with DATA step language - the two are not compatible.

Also you cannot use an ARRAY to reference variables for a rename process because RENAME occurs at the step-level and the ARRAY reference is not.

If you have no need to pass your data, suggest using PROC DATASETS and MODIFY.

You will find useful technical reference material at the SAS support http://suppor.sas.com/ website using the Google advanced argument listed below:

rename all variables site:sas.com

Scott Barry
SBBWorks, Inc.

Re: Rename

SASPhile — Thu, 21 Jan 2010 20:40:31 GMT

Data _null_,
Thanks for the help.
Its neat and nice.
SASPhile.