topic Re: re-base a series in SAS Programming

re-base a series

flyingbear — Mon, 17 Jul 2017 21:35:36 GMT

Hi,

Time series data (CPI, for example) are often indexed to a specific base year such that the value in that year is 1 (or 100) and the values in other years are expressed as ratios to the base year value. I would like to re-base (or re-index) my series to a new base year which simply involves dividing each value by the value in my desired base year. The difficulty is that for the early years, I need to know the value in that later, base year. Does anyone know if there's a simple way to do this (i.e. without getting in to macro programming)?

Thank you all!

Re: re-base a series

ChrisBrooks — Mon, 17 Jul 2017 23:32:48 GMT

You simply select the base year value into a macro variable first and use it in your data step like this

data have;
	input year val;
	datalines;
2000 50
2001 60
2002 70
2003 75
2004 90
2005 100
2006 120
2007 150
2008 155
2009 200
;
run;

/* Store the base year value in a macro variable */

proc sql;
	select val into :base_val
	from have
	where year =2004;
quit;

data want;
	set have;
	index_val=val/&base_val;
run;

Re: re-base a series

gamotte — Tue, 18 Jul 2017 08:08:28 GMT

Hello,

An other possible solution :

data want;
	retain base;

	if _N_=1 then do;
		set have (where=(year=2004));
		base=val;
	end;

	set have;
	index_val=val/base;

	drop base;
run;

Re: re-base a series

flyingbear — Tue, 18 Jul 2017 13:47:49 GMT

Thanks very much!

Re: re-base a series

flyingbear — Tue, 18 Jul 2017 13:50:58 GMT

Thanks! This is very instructive regarding the data step -- helpful for this problem and in the future.