topic Re: base sas in SAS Programming

Add overall total to the data set

shivamarrora0 — Sun, 16 Jul 2017 18:20:13 GMT

Hi all can you Please solve my small problem

data have;
input id name$ marks;
total+marks;
cards;
1 a 10
2 b 20
3 c 30
4 d 40
;
run;

in the above the last observation of total will 100

i want to make a new variable called V and put the last observation of total in every observation of V

i dont want to hardcore the value i want to make it dynamic

output like this

Re: base sas

art297 — Sun, 16 Jul 2017 17:30:15 GMT

Here is one way:

data have;
input id name$ marks;
total+marks;
cards;
1 a 10
2 b 20
3 c 30
4 d 40
;

data want;
  do until (eof1);
    set have end=eof1;
    v+marks;
  end;
  do until (eof2);
    set have end=eof2;
    output;
  end;
run;

Art, CEO, AnalystFinder.com

Re: base sas

Reeza — Sun, 16 Jul 2017 17:38:23 GMT

I'm a fan of SQL for this:

proc sql;
create table want as
select *, sum(marks) as total
from have;
quit;

Another option is to calculate the mean in PROC MEANS and merge in the data:

https://github.com/statgeek/SAS-Tutorials/blob/master/add_average_value_to_dataset

Re: base sas

shivamarrora0 — Sun, 16 Jul 2017 20:08:27 GMT

Hi Reeza,

i know it from proc sql but i want to do it from data step only

Re: base sas

vadday9 — Wed, 19 Jul 2017 07:07:48 GMT

CEO Art297

Thanks for your inputs.

I have used the same code from CEO Art297 and slightly modified to get the expected output.

Shiva,

Can you please check this code.

ata have;
input id name$ marks;
total+marks;
cards;
1 a 10
2 b 20
3 c 30
4 d 40
;

data want;
do until (eof1);
set have end=eof1;
v+marks;
end;
do until (last.marks);
set have ;
output;
end;
run;

proc print;

Re: base sas

art297 — Wed, 19 Jul 2017 14:04:48 GMT

Why would you change the 2nd dow loop until condition? Yes, in this case it will produce the same result, but with a warning that the variable 'last.marks' has never been initialized.

And, if you included a 'by marks' statement in your revised code it would only produce one record.

I suggest you read up on what a DOW loop is and how it works (see: https://www.google.ca/url?sa=t&rct=j&q=&esrc=s&source=web&cd=2&cad=rja&uact=8&ved=0ahUKEwi1yJWywZXVAhVryoMKHSYVA1UQFggvMAE&url=http%3A%2F%2Fsupport.sas.com%2Fresources%2Fpapers%2Fproceedings09%2F038-2009.pdf&usg=AFQjCNEO9qKX1DUwx_xXL7Mn4obLWAP6KQ )

Art, CEO, AnalystFinder.com