topic Re: How to use observations of one dataset as macro variables in another program? in SAS Programming

How to use observations of one dataset as macro variables in another program?

satish78652 — Tue, 11 Jul 2017 04:19:26 GMT

Hi Mate,

I need help from you guys. Let me explain you my problem firtst. I have created a single variable dataset (All the observation of this dataset are variables for my other programming.). Now i need to use the observations in a sequence like 1st observation and 2nd observation will be considered as Macro variables "START" and "STOP" in another programe and once the macro finishes forst ittration then 2nd observation should be "START" and 3rd observation should be "STOP" variable. Like this, the entire observations need to be used as derived Macro variables in another programme.

Example:

Dataset_1

obs Title

01 Name

02 age

03 sex

04 address

05 language

Programme:

%macro test (Start= , Stop= );

if var1= &START then Seq+1;

if var1= &STOP then seq+1;

if seq=1 or var1= &STOP;

%mend test;

Please provide me a solution to use the observation of dataset_1 as macro variables in the above programe in the above specified sequence.

Thanks

Re: How to use observations of one dataset as macro variables in another program?

Reeza — Tue, 11 Jul 2017 05:22:39 GMT

Look at CALL EXECUTE if I understand your question correctly. It's ambiguous.

The example in the documentation shows how a dataset can drive a macro.

Re: How to use observations of one dataset as macro variables in another program?

ChrisNZ — Tue, 11 Jul 2017 05:29:29 GMT

Like this?

data HAVE;
input VAR $;
cards;
Name
age
sex
address
language
run;
proc sql noprint;
  select VAR into :varlist separated by ' ' from HAVE;
quit;

%macro test(start=, stop=);
  %put Replace with actual code &=start &=stop;
%mend;

%macro loop;
   %local i;
    %do i=1 %to &sqlobs.-1;
      %test(START=%scan(&varlist, &i),STOP=%scan(&varlist, &i+1));
  %end;
%mend;
%loop;

Replace with actual code START=Name STOP=age
Replace with actual code START=age STOP=sex
Replace with actual code START=sex STOP=address
Replace with actual code START=address STOP=language

Re: How to use observations of one dataset as macro variables in another program?

ChrisNZ — Tue, 11 Jul 2017 05:35:42 GMT

Or like this?


data _null_;
  set HAVE;
  PREV=lag(VAR);
  if PREV ne ' ' then 
  call execute('%test(start='||PREV||',stop='||VAR||');');
run;

Re: How to use observations of one dataset as macro variables in another program?

satish78652 — Tue, 11 Jul 2017 06:24:32 GMT

The programme provided is working only for numeric variables. Can you please modify it to work for character variable as well?

Re: How to use observations of one dataset as macro variables in another program?

ChrisNZ — Tue, 11 Jul 2017 06:35:59 GMT

How is "Name" a numeric?

Re: How to use observations of one dataset as macro variables in another program?

satish78652 — Tue, 11 Jul 2017 06:37:51 GMT

the programe is not working for the variables like name, address and language.

Re: How to use observations of one dataset as macro variables in another program?

ChrisNZ — Tue, 11 Jul 2017 06:39:01 GMT

It is and I even provided the outputs

Re: How to use observations of one dataset as macro variables in another program?

satish78652 — Tue, 11 Jul 2017 07:25:21 GMT

Thank you for your help Chriz. Now i got it.