topic Re: Expected close parenthesis error in loop over macro in SAS Programming

Expected close parenthesis error in loop over macro

csetzkorn — Thu, 22 Jun 2017 18:03:54 GMT

I am getting a:

Expected close parenthesis after macro function invocation not found

fro this code:

data _null_;
  set LoopData;
  call execute('%nrstr(%SomeMacro('||ColumnName||'))');
run;

Cannot see anything wrong. Any ideas?

Re: Expected close parenthesis error in loop over macro

Quentin — Thu, 22 Jun 2017 18:27:31 GMT

Agree, that bit looks fine. Maybe there's a problematic macro call inside of %SomeMacro, or maybe your ColumnName variable has an unmatched open parenthesis in it.

I tested your code with below, and worked fine:

%macro somemacro(columnName);
  proc print data=sashelp.class;
    var &columnName;
  run;
%mend somemacro;

data loopdata;
  input columnName $8.;
  cards;
sex
weight
height
;
run;

data _null_;
  set LoopData;
  call execute('%nrstr(%SomeMacro('||ColumnName||'))');
run;

I would try calling %SomeMacros manually (i.e., without CALL EXECUTE), and make sure it works. Then I would look at all the values in ColumnName to check for any surprises.

Re: Expected close parenthesis error in loop over macro

csetzkorn — Thu, 22 Jun 2017 19:17:06 GMT

Thanks I removed brackets from ColumnName because I thought exactly this. Turned out to be some legacy being commented out which screwed the code.

Re: Expected close parenthesis error in loop over macro

Tom — Thu, 22 Jun 2017 19:20:18 GMT

Personally when using CALL EXECUTE() to generate macro calls I wrap the %NRSTR() macro function just around the macro name itself and leave the macro parameters without macro quoting.

data _null_;
  set LoopData;
  call execute(cats('%nrstr(%SomeMacro)(',ColumnName,')'));
run;

Are you sure that the value of ColumnName does not contain '()' characters?