topic How to remove multiple '_' and number in the string? in SAS Programming

How to remove multiple '_' and number in the string?

ybz12003 — Thu, 22 Jun 2017 14:09:13 GMT

Hello:

I have the following data. I would like to remove all of the '_' and assign what the number in the string at the end. Please help. Thanks.

data have;

input Names$100.;

cards;

lab_den_pcr_perf_1

mhh_cyto_tests_1__cfdna

nad_cert_30

nad_imag_find2___abn_cort_gyr

;

run;

The result I am looking for is

labdenpcrperf1

mhhcytotestscfdna1

nadcert30

nadimagfindabncortgyr2

Re: How to remove multipul '_' and number in the string?

PeterClemmensen — Thu, 22 Jun 2017 12:13:01 GMT

You can use the COMPRESS function to remove certain characters from a string. Not sure what you mean by "assign what the number in the string at the end". Do you want to have the number of occurences of "_" at the end of each string?

Re: How to remove multipul '_' and number in the string?

Patrick — Thu, 22 Jun 2017 12:24:09 GMT

@ybz12003

Providing a "desired result" would help us to better understand what you're after.

The following code will populate a numeric variable with a number if digits only are found as the last element of your source string (with underscore separating the "elements").

data have;
  input Names :$100.;
  cards;
lab_den_pcr_perf_1
mhh_cyto_tests_1__cfdna
nad_cert_30
nad_imag_find2___abn_cort_gyr
;
run;

data want;
  set have;
  no_at_end_of_str=input(scan(names,-1,'_'),?? best32.);
run;

Re: How to remove multipul '_' and number in the string?

RW9 — Thu, 22 Jun 2017 12:55:57 GMT

Something like:

data want;
  set have;
  names=cats(compress(names,"_","ka"),compress(names,"_","kd"));
run;

Re: How to remove multipul '_' and number in the string?

Astounding — Thu, 22 Jun 2017 13:14:19 GMT

Here's a way:

data want;

set have;

prefix = compress(names, '_0123456789');

suffix = compress(names, , 'kd' );

names = strip(prefix) || suffix;

drop prefix suffix;

run;

One caution: If there are multiple sets of digits, all of them get combined and put at the end. For example:

abc1_xyz2_def becomes abcxyzdef12

Re: How to remove multipul '_' and number in the string?

DoumbiaS — Thu, 22 Jun 2017 13:21:53 GMT

Like this ?

data want;

set have;

n_position= anydigit(names,1);

number= compress(substr(names,n_position),,"kd");

names_want= cats(compress(names,'_',"d"),number);

keep names_want;

run;

Re: How to remove multipul '_' and number in the string?

kiranv_ — Thu, 22 Jun 2017 13:24:34 GMT

something like this in regex

data want;
set have;
name = prxchange('s/_|([^\d]+$)//', -1, names);
run;

Re: How to remove multipul '_' and number in the string?

jdwaterman91 — Thu, 22 Jun 2017 16:20:52 GMT

@RW9

Specifying the k-modifier in the compress function keeps the "_" instead of removing it.

I also think he wants the numbers at the end of the string instead of the beginning.

So modifying your code, I think this will work:

data want2;
  set have;
  names=cats(compress(names,"_","d"), compress(names,"_","a"));
run;

Re: How to remove multipul '_' and number in the string?

RW9 — Thu, 22 Jun 2017 16:25:23 GMT

Actually my code is fine, just remove the _, whiich I added in haste:

data want;
  set have;
  names=cats(compress(names,"","ka"),compress(names,"","kd"));
run;

Re: How to remove multipul '_' and number in the string?

ybz12003 — Fri, 23 Jun 2017 19:14:08 GMT

I start to understand what the prxchange means.

Re: How to remove multiple '_' and number in the string?

Patrick — Sat, 24 Jun 2017 05:49:34 GMT

@ybz12003

The following code returns the desired output as you've posted.

Based on your narrative I'm not sure if this really is what you're after. If not then please post some additional sample data where it's not working for you.

data have;
  input Names :$100.;
  cards;
lab_den_pcr_perf_1
mhh_cyto_tests_1__cfdna
nad_cert_30
nad_imag_find2___abn_cort_gyr
;
run;

data want;
  set have;
  length names_want $100;
  names_want=cats(compress(Names,'_','d'),compress(Names,,'kd'));
run;