topic Re: add a value in multiple columns in SAS Programming

add a value in multiple columns

echoli — Wed, 14 Jun 2017 16:20:15 GMT

Hi All,

I have a dataset below:

data want;
  input Group $ Timepoint GM FRO CONT RES;
datalines;
A 1 3 2 5 2
A 2 2 3 3 8
A 1 4 3 5 6
A 2 5 4 3 7
B 1 6 4 3 5
B 2 5 4 3 6
B 1 4 5 2 7
;

How can I add 5 for GM - RES if timepoint = 1?

Thanks,

Re: add a value in multiple columns

BrunoMueller — Wed, 14 Jun 2017 16:25:18 GMT

Use an array, so you can do the same operation on many variables.

see here for some more details https://support.sas.com/resources/papers/97529_Using_Arrays_in_SAS_Programming.pdf

Re: add a value in multiple columns

kiranv_ — Wed, 14 Jun 2017 16:45:02 GMT

By sql you can as follows

proc sql;
create table newwant as 
select group
        ,timepoint
            ,case when Timepoint = 1 then GM*5 else GM end as GM
			,case when Timepoint = 1 then FRO*5 else FRO end as FRO
			,case when Timepoint = 1 then CONT*5 else CONT end as CONT
			,case when Timepoint = 1 then RES*5 else RES end as RES
			from want;
quit;

Re: add a value in multiple columns

PeterClemmensen — Wed, 14 Jun 2017 16:52:49 GMT

data have;
  input Group$ Timepoint GM FRO CONT RES;
datalines;
A 1 3 2 5 2
A 2 2 3 3 8
A 1 4 3 5 6
A 2 5 4 3 7
B 1 6 4 3 5
B 2 5 4 3 6
B 1 4 5 2 7
; 

data want(drop = i);
   set have;
   array vars{*} GM FRO CONT RES;
   if timepoint = 1 then do i = 1 to dim(vars);
      vars[i] = vars[i] + 5;
   end;
run;

Re: add a value in multiple columns

CatCol — Wed, 14 Jun 2017 17:05:43 GMT

Try this:

data wantnew;
set want;
array val{4} GM FRO CONT RES;
if Timepoint=1 then do i=1 to 4;
val{i}=Val{i}+5;
end;
drop i;
run;