topic Re: set variable equal to a randomly chosen value from a list in SAS Programming

set variable equal to a randomly chosen value from a list

the_sheriff — Wed, 07 Jun 2017 06:09:44 GMT

Hello,

I am attempting the following for each observation in my dataset.

x=SelectRandomlyFrom("A","B","C")

That's it. I can use ranuni or proc surveyselect to select one of the options but i can't figure out how to set x equal to the output.

it doesn't matter to me if my choices have to be in a dataset or simply a typed list.

Any help would be appreciated.

thank you.

Re: set variable equal to a randomly chosen value from a list

Yegen — Wed, 07 Jun 2017 06:31:11 GMT

If you only want to select random As, Bs, and Cs, the following code will take care of it:

data work.want;
	do i=1 to 10;
	random_ABC = substr('ABC',ceil(ranuni(0)*3),1);
	output;
   	end;
run;

Re: set variable equal to a randomly chosen value from a list

Reeza — Wed, 07 Jun 2017 06:43:55 GMT

RANTBL() function.

http://support.sas.com/documentation/cdl/en/lefunctionsref/69762/HTML/default/viewer.htm#n1kxey71grroain1k5e0j8n69vj3.htm

Re: set variable equal to a randomly chosen value from a list

s_lassen — Wed, 07 Jun 2017 10:56:28 GMT

@the_sheriff: The CHOOSEC is probably the easiest way in your example:

x=ChooseC(ceil(Rand('UNIFORM')*3),"A","B","C");

If your data is in an array, this is the format:

array values c1-c60;
x=ChooseC(ceil(Rand('UNIFORM')*dim(values)),of values(*));

I recommend using RAND() instead of RANUNI(), as it is a better pseudorandom algorithm.

Re: set variable equal to a randomly chosen value from a list

Rick_SAS — Wed, 07 Jun 2017 12:56:32 GMT

You can generalize @s_lassen's solution to the case of unequal probabilities, as described in the blog post

"Simulate categorical data in SAS"

data Sample; 
keep i j x; 
array prob [3] (0.5 0.2 0.3);       /* unequal probabilities */
array values [3] $ ("A" "B" "C"); /* categories */
call streaminit(54321); 
do i = 1 to 100;
   j = rand("Table", of prob[*]);
   x = values[j];
   output; 
end; 
run;

Re: set variable equal to a randomly chosen value from a list

the_sheriff — Wed, 07 Jun 2017 14:32:23 GMT

Always great to learn something new. This is exactly what i was looking for. Thank you.