topic How to specify plot markers for proc sgplot with attribute map? in SAS Programming

How to specify plot markers for proc sgplot with attribute map?

user42 — Tue, 06 Jun 2017 22:31:07 GMT

I'm trying to implement the solution given in the forum post Proc sgplot: plotting different colors and markers for several groups in a scatter plot, but my plot markers are not changing with group. Here's my code:

* Create attribute map;
data plotattrs;
	retain id "myid";
	length value 3.0 markercolor $ 6 markersymbol $ 6;
	input value markercolor $ markersymbol $;
	datalines;
		1 red plus
		2 green x
	;
run;

* Plot data;
proc sgplot
		data = sashelp.iris
		dattrmap = plotattrs;
	scatter x = petallength y = petalwidth /
		group = species
  		attrid = myid;
run;

The plot that is generated represents group by color, but not by marker type:

How can I make the plot marker type vary with group like the marker color does?

Re: How to specify plot markers for proc sgplot with attribute map?

ballardw — Tue, 06 Jun 2017 23:03:35 GMT

The value has to match the value of the group variable.

Try

data plotattrs;
	retain id "myid";
	length value $ 10 markercolor $ 6 markersymbol $ 6;
	input value markercolor $ markersymbol $;
	datalines;
		Setosa red plus
		Versicolor2 green x
      Virginica blue  diamond
	;
run;

* Plot data;
proc sgplot
		data = sashelp.iris
		dattrmap = plotattrs;
	scatter x = petallength y = petalwidth /
		group = species
  		attrid = myid;
run;

Re: How to specify plot markers for proc sgplot with attribute map?

user42 — Tue, 06 Jun 2017 23:06:56 GMT

Thank you-- I knew I was missing something basic.

Re: How to specify plot markers for proc sgplot with attribute map?

ballardw — Tue, 06 Jun 2017 23:18:52 GMT

You may also want to consider using longer text fields by default for you options just so you don't do what I did and tryto stuff "diamond" into a 6 character field.

Re: How to specify plot markers for proc sgplot with attribute map?

user42 — Tue, 06 Jun 2017 23:20:25 GMT

Yeah, I actually caught that one. 🙂

Re: How to specify plot markers for proc sgplot with attribute map?

Ksharp — Wed, 07 Jun 2017 13:19:37 GMT

ods graphics / attrpriority=none;
proc sgplot	data = sashelp.iris;
 styleattrs datacolors=(red yellow blue) ;
	scatter x = petallength y = petalwidth /
	jitter	group = species;
run;

Re: How to specify plot markers for proc sgplot with attribute map?

user42 — Wed, 07 Jun 2017 14:47:14 GMT

Thanks for this, Ksharp. I wasn't aware of the "styleattrs" statement in proc sgplot.