topic Re: How to remove numbers from charater variable in SAS Programming

How to remove numbers from charater variable

ybz12003 — Mon, 05 Jun 2017 14:56:06 GMT

Hello, all:

I would like to remove the last number from the ID column. I have 300 ID names which need to do this repeatly. Please let me know how, thanks.

data state;

input ID $;

cards;

TN1

TN2

TN3

UCH1

UCH2

UCH3

UCH4

UCH5

ICFG1

ICFG2

ICFG3

ICFG4

ICFG5

ICFG6

;

run;

Re: How to remove numbers from charater variable

Shmuel — Mon, 05 Jun 2017 15:09:19 GMT

There are several ways to remove the numbers:

data state;
input ID $;
/*1*/ id = translate(id,'','0123456789');
/*2*/ id = compress(id,'0123456789');
/*3*/ id = compress(id,' ','D');
cards;
... your data ...
run;

Re: How to remove numbers from charater variable

Jagadishkatam — Mon, 05 Jun 2017 15:20:27 GMT

data state;
input ID $;
new=prxchange('s/\d$/ /',-1,strip(id));
cards;
TN1
TN2
TN3
UCH1
UCH2
UCH3
UCH4
UCH5
ICFG1
ICFG2
ICFG3
ICFG4
ICFG5
ICFG6
;
run;

Re: How to remove numbers from charater variable

RW9 — Mon, 05 Jun 2017 15:09:00 GMT

You could also do:

id = compress(id,,'ka');

K=Keep, A=Alpha.

http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a000212246.htm

Might be a bit shorted if you had other things as there are a few options in compress.

Re: How to remove numbers from charater variable

art297 — Mon, 05 Jun 2017 15:13:42 GMT

If you only want to remove one digit if it exists at the end of an id you could use:

data want;
  set state;
  if findc(id,,'db') then id=substr(id,1,findc(id,,'db')-1);
run;

Art, CEO, AnalystFinder.com

Re: How to remove numbers from charater variable

ybz12003 — Mon, 05 Jun 2017 15:23:32 GMT

What is the 'db' refering?

Re: How to remove numbers from charater variable

art297 — Mon, 05 Jun 2017 15:28:01 GMT

find a digit, searching from right to left. And, as I think about it, the code I suggested should actually have been:

data want;
  set state;
  if findc(id,,'db') eq length(id) then id=substr(id,1,findc(id,,'db')-1);
run;

i.e., only remove the last character .. if it is a digit.

Art, CEO, AnalystFinder.com

Re: How to remove numbers from charater variable

ybz12003 — Mon, 05 Jun 2017 19:43:30 GMT

Thanks for your kind help.

Re: How to remove numbers from charater variable

lalohg — Thu, 07 Jun 2018 17:51:53 GMT

HI Art,

could you please let me know how to remove entries with at least one number (any number) of a character variable?

Re: How to remove numbers from charater variable

lalohg — Thu, 07 Jun 2018 17:52:06 GMT

HI Art,

could you please let me know how to remove entries with at least one number (any number) of a character variable?

Thanks

Lalo

Re: How to remove numbers from charater variable

art297 — Thu, 07 Jun 2018 19:20:23 GMT

Just use the anydigit function. i.e.,

if anydigit(varname) then call missing(varname);

Art, CEO, AnalystFinder.com

Re: How to remove numbers from charater variable

lalohg — Fri, 08 Jun 2018 11:52:36 GMT

Thank you very much

Have a good day.

Lalo.