topic Re: Select most recent rows with changed value only in SAS Programming

Select most recent rows with changed value only

DeepakSwain — Fri, 02 Jun 2017 12:59:46 GMT

Hi there,

For your kind information, I am trying to identify only those records which have been submitted with some changes. For example in the table mentioned below, TYPE has been changed in the most recent report with reference to the earliest report submitted.

data have ;
format date_1 date9. ;
input id $ sp_num $ type $  date_1 yymmdd8.;
datalines;
101 a01 p 20160102
101 a01 b 20160103
102 b02 b 20160104
102 b02 b 20160105
103 c03 p 20160106
103 c03 p 20160107
103 c03 b 20160108
;
run;


data want ;
format date_1 date9. ;
input id $ sp_num $ type $  date_1 yymmdd8.;
datalines;
101 a01 b 20160103
103 c03 b 20160108
;
run;

Can anybody kindly guide me to get it.

Thank you in advance.

Regards,

Re: Select most recent rows with changed value only

art297 — Fri, 02 Jun 2017 13:08:46 GMT

did you also want the following record in your want dataset?:

102 b02 b 20160105

Art, CEO, AnalystFinder.com

Re: Select most recent rows with changed value only

art297 — Fri, 02 Jun 2017 13:19:08 GMT

I think I answered my own question. Are you looking to do something like?:

data want (drop=change);
  set have;
  by id sp_num;
  retain change;
  if first.sp_num then change=0;
  if type ne lag(type) and not first.sp_num then change=1;
  if change and last.sp_num then output;
run;

Art, CEO, AnalystFinder.com

Re: Select most recent rows with changed value only

DeepakSwain — Fri, 02 Jun 2017 13:28:14 GMT

Hi art297,

As the value of type has not changed, that record is not included.

Regards,

Re: Select most recent rows with changed value only

DeepakSwain — Fri, 02 Jun 2017 13:47:50 GMT

Hi art297,
The advice given is great !
Can you advice me further to identify all records having change in TYPE with reference to the first one.
Regards,

Re: Select most recent rows with changed value only

art297 — Fri, 02 Jun 2017 14:15:43 GMT

In order to identify all instances where type is different than the initial value for type, I'd suggest a slightly different approach:

data have ;
  format date_1 date9. ;
  input id $ sp_num $ type $  date_1 yymmdd8.;
  datalines;
101 a01 p 20160102
101 a01 b 20160103
102 b02 b 20160104
102 b02 b 20160105
103 c03 p 20160106
103 c03 p 20160107
103 c03 b 20160108
103 c03 b 20160109
;
run;

data want (drop=change);
  set have;
  by id sp_num;
  retain first_type;
  if first.sp_num then first_type=type;
  else if type ne first_type then output;
run;

Art, CEO, AnalystFinder.com

Re: Select most recent rows with changed value only

DeepakSwain — Fri, 02 Jun 2017 14:46:13 GMT

Hi art297,

Thanks for taking the pain to answer my silly questions. It has been a good learning experience.

Regards,