topic Re: Proc means for a list of variables start with _ in SAS Programming

Proc means for a list of variables start with _

hhchenfx — Fri, 02 Jun 2017 02:15:35 GMT

Hi,

I want to run a proc means for a list of variables that start with _

	proc means data=PL noprint;
	var _:;
	by type;
	output out=PL_sum
	sum= _:;
	run;

The problem is with SUM=_:

Is there any way to let SAS keep the original name for variable in output file?

Thank you,

Re: Proc means for a list of variables start with _

Reeza — Fri, 02 Jun 2017 02:19:20 GMT

1. Check if the ODS tables work better for you.

2. There is the AUTONAME option but it ends up being the variable_statistic type format. It may work for you, but it isn't the original variable name.

Re: Proc means for a list of variables start with _

hhchenfx — Fri, 02 Jun 2017 02:38:24 GMT

Thanks,

I use that ODS and Transpose to get what I want.

However, there is a minor issue related to the number format.

In the TEMP_ file, some numbers are 2 decimal place, some are rounded.

Is there anyway to choose the format of the number in the TEMP_File?

Thanks


ods listing close;
ods output summary=TEMP_;
proc means data=PL stackods SUM;
	by Type;
run;
ods output close;
ods listing;
run;

proc transpose data=TEMP_ out=WANT ;
by Type;
var sum;
id variable;
run;

Re: Proc means for a list of variables start with _

Reeza — Fri, 02 Jun 2017 02:40:53 GMT

Apply a format to the new variables. Most likely the underlying variables have the decimal values as well.

Usually you use STACKODS and don't transpose or don't use STACKODS.

Did not using STACKODS give you what you want directly?

Re: Proc means for a list of variables start with _

hhchenfx — Fri, 02 Jun 2017 02:45:35 GMT

Nice, No stackods is better.
But the name ending with _sum, which is understandable.
Is there any way to get rid of that _SUM all together? It is not efficient to write 30 rename.

HC

Re: Proc means for a list of variables start with _

Reeza — Fri, 02 Jun 2017 02:54:02 GMT

You don't need that. Your original code was correct, you just needed to not list any variables in the SUM statement, since you'd already done so in the VAR statement.

proc means data=class SUM noprint;
	by sex;
	var weight height age;
	output out=want sum=;
run;

proc print data=want;
run;

Re: Proc means for a list of variables start with _

ChrisNZ — Fri, 02 Jun 2017 02:56:18 GMT

What's wrong with


proc means data=PL(keep=TYPE _:) noprint;
  by TYPE;
  output out=SUM sum=;
run;

Re: Proc means for a list of variables start with _

hhchenfx — Wed, 07 Jun 2017 18:51:50 GMT

Thanks a lot for your helps.

HHC