topic calculations in PROC SQL in SAS Programming

calculations in PROC SQL

GreggB — Wed, 31 May 2017 14:01:45 GMT

(I know I should know this). I want to get rid of the hard coded number (10021). This number equals the number of records in the data set.

My objective is to count the number of obs in each efaprimary category listed in the WHERE clause and then get a percentage that it represents of the entire data set. In other words, there are some efaprimary codes not included in the report but I need to count those obs to use in the denominator.

proc sql;
SELECT d.efaprimary, count(efaprimary) as Ncount,
calculated Ncount/10021 as Pct format=percent8.2
FROM d45 as d
WHERE enroll_status='0' and grade_level not in ('-1','-2') and efaprimary in ('*DD','*OHI','*PMD','*TBI','AU','EH','EM','HH','LD','OH','SP','TM','VH')
GROUP BY efaprimary;
QUIT;

Re: calculations in PROC SQL

Kurt_Bremser — Wed, 31 May 2017 14:19:20 GMT

proc sql noprint;
select nobs into :nobs from dictionary.tables where libname = 'WORK' and upcase(memname) = 'D45';
quit;

Now you can use &nobs instead of 10021.

Re: calculations in PROC SQL

GreggB — Wed, 31 May 2017 14:08:06 GMT

should "info" be "in" ?

Re: calculations in PROC SQL

art297 — Wed, 31 May 2017 14:14:53 GMT

One way would be to include the total n as a subquerry. e.g.:

proc sql;
  SELECT d.sex, count(sex) as Ncount,
    (select count(*) from sashelp.class) as total,
    calculated Ncount/calculated total as Pct format=percent8.2
      FROM sashelp.class as d
        WHERE age le 12
          GROUP BY sex
  ;
QUIT;

Art, CEO, AnalystFinder.com

Re: calculations in PROC SQL

GreggB — Wed, 31 May 2017 14:18:01 GMT

Thanks.

Re: calculations in PROC SQL

Kurt_Bremser — Wed, 31 May 2017 14:18:40 GMT

@GreggB wrote:

should "info" be "in" ?

Actually, it should be "into". Typo, fixed it.