topic Re: Adding more decimals to the proc freq procedure in SAS Programming

Adding more decimals to the proc freq procedure

BenBrady — Mon, 29 May 2017 07:14:23 GMT

I want to add more decimal places to the percent column of the output created by proc freq in sas. I have a percent now of 87.76 but I would like this to 4 decimal places. The template for this is Base.Freq.OneWayFreqs. The code I am currently using is:

proc freq data=cat;

table food;

weight weight;

run;

Re: Adding more decimals to the proc freq procedure

SASKiwi — Mon, 29 May 2017 07:54:25 GMT

One way to get what you want is to output a table in PROC FREQ and then use PROC PRINT as this example shows:

http://support.sas.com/documentation/cdl/en/procstat/68142/HTML/default/viewer.htm#procstat_freq_examples01.htm

Re: Adding more decimals to the proc freq procedure

SuzanneDorinski — Mon, 29 May 2017 17:18:56 GMT

You can edit the template.

* use ODS PATH statement so that you don't overwrite templates ;
* that shipped with SAS! ;

ODS PATH WORK.TEMPLAT(UPDATE) SASHELP.Tmplmst(READ);

proc template;
  edit Base.Freq.OneWayList;  
	edit Percent;
	  format=7.4 ;           
	end;
	edit CumPercent;
	  format=7.4 ;
	end;
  end;
run;

proc freq data=sashelp.class;
  tables height weight;
run;

* delete the edited template ;

proc template;
  delete Base.Freq.OneWayList;
run;