topic Re: Using cntlin in proc format when one of the values is 'LOW' in SAS Programming

Using cntlin in proc format when one of the values is 'LOW'

art297 — Sat, 27 May 2017 15:38:33 GMT

Ran into an interesting problem last night when using the cntlin option with proc format. The following code produces an error:

data for_format;
  input sym_root $;
  cards;
AAA
BBB
LOW
ZZZ
;
run;

data for_format;
  set for_format (rename=(sym_root=start));
  retain fmtname "$labelfmt" type "C";
  label=_n_;
run;

proc format cntlin = for_format;
run ;

Anyone know how one can include the value 'LOW' in such a case? My work around was to recode 'LOW' to be 'LOWW', but I'd rather no have to change the variable's value.

Art, CEO, AnalystFinder.com

Re: Using cntlin in proc format when one of the values is 'LOW'

Tom — Sat, 27 May 2017 16:37:42 GMT

You need to add the HLO variable to your control dataset to prevent SAS from trying to detect the LOW HIGH keywords from the text of the START/END values.

data for_format;
  set have (rename=(sym_root=start));
  retain fmtname "$labelfmt" type "C" hlo '   ';
  label=_n_;
run;
proc format cntlin = for_format;
run ;

One way to test is to make the format using code and output the control dataset.

Then try keeping different subsets of the variables in that control dataset to pass back into PROC FORMAT to figure out the minimum set of variables that are needed.

proc format cntlout=want;
  value $labelfmt
  'AAA'='1'
  'BBB'='2'
  'LOW'='3'
  'ZZZ'='4'
  ;
run;

proc format cntlin=want(keep=fmtname type start label hlo); 
run;

Re: Using cntlin in proc format when one of the values is 'LOW'

art297 — Sat, 27 May 2017 16:48:35 GMT

@Tom: Worked like a charm!

Thanks,

Art