topic Re: where is the problem for this macro variable reference? in SAS Programming

where is the problem for this macro variable reference?

ifendo — Fri, 26 May 2017 03:33:04 GMT




%macro test1;
    data a;
    a=1;
    put "a long text";
    run;
%mend;
%test1;       * this works;


%let long=%nrbquote(%test1);
%put &long;

options mprint mlogic symbolgen;
%macro test2;
%if &long ne %str( ) %then %do;
    data b;
    b=1;
%end;
 &long  /* problem here, why? */
proc print width=min;
run;
%mend;

%test2;

I was about to check some macros, but happened to find this error while testing, where is the problem?

Thank you very much

Re: where is the problem for this macro variable reference?

Reeza — Fri, 26 May 2017 04:17:15 GMT

What happens if you add a semicolon after &long?

Re: where is the problem for this macro variable reference?

ifendo — Fri, 26 May 2017 04:31:56 GMT

Thank you, Reeza. I still got the same error if i add a semicolon...

but if i remove the the put "a long text" , it works, do not know why

Re: where is the problem for this macro variable reference?

kanivan51 — Fri, 26 May 2017 05:45:51 GMT

%macro test1;
%do;
data a;
a=1;
%put a long text; /*There must be a sign "%"*/
run;
%end;
%mend;
%test1;

%let long=%nrbquote(%test1);
%put &long;

options mprint mlogic symbolgen;
%macro test2;
%if &long ne %str( ) %then %do;
data b;
b=1;
run;
%end;
&long /* problem here, why? */
proc print width=min;
run;
%mend;
%test2;

Re: where is the problem for this macro variable reference?

Astounding — Fri, 26 May 2017 12:17:20 GMT

The contents of &long have been quoted by %NRBQUOTE. That includes the double quotes surrounding "a long text". Evidently, SAS isn't figuring out to unquote those in time to parse the statement correctly. Try replacing this:

&long

Instead, use:

%unquote(&long)

Re: where is the problem for this macro variable reference?

Ksharp — Fri, 26 May 2017 12:41:55 GMT

Try %UNQUOTE()

%macro test1;
    data a;
    a=1;
    put "a long text";
    run;
%mend;
%test1


%let long=%nrbquote(%test1);
%put &long;

options mprint mlogic symbolgen;
%macro test2;
%if &long ne  %then %do;
    data b;
    b=1;
    run;
%end;
 %unquote(&long) 
proc print width=min;
run;
%mend;

%test2;

Re: where is the problem for this macro variable reference?

Tom — Fri, 26 May 2017 13:25:58 GMT

The macro quoting introduced by the %NRBQUOTE() function is causing the generated code to not be valid SAS syntax.

Use the %UNQUOTE() function to remove the macro quoting when you no longer need it.

Here is a simplier example.

%let mvar1=put "no macro quoting";
%let mvar2=%nrbquote(put "macro quoting");
data _null_;
 &mvar1;
run;
data _null_;
 &mvar2;
run;
data _null_;
 %unquote(&mvar2);
run;

Re: where is the problem for this macro variable reference?

ifendo — Fri, 26 May 2017 14:02:04 GMT

Thank you very much for the explanation

Re: where is the problem for this macro variable reference?

ifendo — Fri, 26 May 2017 14:02:38 GMT

Thank you all