topic Change value in a dataset in SAS Programming

Change value in a dataset

mgerberhome0 — Tue, 16 May 2017 10:06:10 GMT

Hi,

How can I write this as a datastep to change the actual values stored in the variable 'LBTEST' in 9.4?

If I use the below Proc format and then Proc Print the updated values show, but how can I save the updated dataset?

proc format;
value $LBTEST

'Albumin (Alb)'='Albumin'
'Alanine aminotransferase (ALT)'='Alanine aminotransferase'
'Alkaline phosphatase (ALP)'='Alkaline phosphatase'
'Aspartate aminotransferase (AST)'='Aspartate aminotransferase'
'Basophils - % (Baso %)'='Basophils (%)'
'Basophils - Absolute (Baso Abs)'='Basophils (Abs)'
'Blood urea nitrogen (BUN)'='Blood urea nitrogen'
run;

proc print data=ABNLABKEEP;
format LBTEST $LBTEST.;
run;

Re: Change value in a dataset

novinosrin — Tue, 16 May 2017 10:11:26 GMT

Do you mean ?:

data ABNLABKEEP;

set ABNLABKEEP;

format LBTEST $LBTEST.;
run;

Re: Change value in a dataset

Astounding — Tue, 16 May 2017 10:27:11 GMT

To actually change the values:

data WANT;

set ABNLABKEEP;

LBTEST = put(LBTEST, $LBTEST.);
run;

Re: Change value in a dataset

ballardw — Tue, 16 May 2017 14:43:28 GMT

Or perhaps make that format an INVALUE and use it as an INFORMAT to read the data. This may be a better option in the long run if you are reading multiple files with the same contents.

Re: Change value in a dataset

mgerberhome0 — Tue, 16 May 2017 22:33:07 GMT

Thanks!

I get an error....

Re: Change value in a dataset

art297 — Tue, 16 May 2017 22:59:11 GMT

I have to guess that you made some kind of mistake in creating the format. The following works for me:

data ABNLABKEEP;
  informat lbtest $80.;
  input lbtest &;
  cards;
Albumin (Alb)
Alanine aminotransferase (ALT)
Alkaline phosphatase (ALP)
Aspartate aminotransferase (AST)
Basophils - % (Baso %)
Basophils - Absolute (Baso Abs)
Blood urea nitrogen (BUN)
;

proc format;
value $LBTEST
        'Albumin (Alb)'='Albumin'
       'Alanine aminotransferase (ALT)'='Alanine aminotransferase'
       'Alkaline phosphatase (ALP)'='Alkaline phosphatase'
      'Aspartate aminotransferase (AST)'='Aspartate aminotransferase'
   'Basophils - % (Baso %)'='Basophils (%)'
  'Basophils - Absolute (Baso Abs)'='Basophils (Abs)'
 'Blood urea nitrogen (BUN)'='Blood urea nitrogen'
run;

data WANT;
set ABNLABKEEP;
LBTEST = put(LBTEST, $LBTEST.);
run;

Art, CEO, AnalystFinder.com